Public Class frmLagerHaltung
 
    'Datatable und Grid für Lagertabelle 
    Dim dt As New DataTable
    Dim dgv As New DataGridView With
        {.Parent = Me, .Top = 10, .Left = 10, .Width = 300, .Height = 200,
        .DataSource = dt}
 
    Dim WithEvents btnÜbertragung As New Button With
        {.Parent = Me, .Text = "Übertrag", .Top = 220, .Left = 10}
 
 
    Private Sub frmLagerHaltung_Load(sender As Object, 
                                     e As EventArgs) Handles MyBase.Load
 
        Dim rndm As New Random
 
        'Eine einfache Teileliste erstellen
        With dt
            With .Columns
                .Add("Artikel", GetType(String))
                .Add("Anzahl", GetType(Integer))
            End With
            With .Rows
                For i As Integer = 65 To 80
                    .Add(Chr(i), rndm.Next(10, 100))
                Next
            End With
            .PrimaryKey = {dt.Columns("Artikel")}
        End With
 
    End Sub
 
 
    Private Sub btnÜbertragung_Click(sender As Object, 
                         e As EventArgs) Handles btnÜbertragung.Click
 
        'Eine Bestellung als eingelesene CSV per Methode <IO.Readalllines>
        Dim bestellung() As String = {"Maier;C;12",
                                      "Maier;F;17",
                                      "Maier;P;9"}
 
        For i As Integer = 0 To bestellung.Length - 1
            Dim posten() As String = bestellung(i).Split(";"c)
            'in Posten(0) steht Kunde, in posten(1) steht Teilebez. ,
            'in posten(2) bestellte Anzahl
 
            'Zeile in Teiletabelle ermitteln gemäß Teilebezeichnung (Schlüssel)
            'aus der CSV-Zeile 
            Dim row As DataRow = dt.Rows.Find(posten(1))
 
            'Anzahl in posten(2) vom Lagerbestand abziehen
            Dim TeileImLager As Integer = CInt(row.Item("Anzahl"))
            row.Item("Anzahl") = TeileImLager - CInt(posten(2))
        Next i
 
        'Jetzt kann ein Update der Datenbank erfolgen
 
    End Sub
End Class