Private Sub Button_StartStop_Click(ByVal sender As System.Object, ByVal e _
      As System.EventArgs) Handles Button_StartStop.Click
 
        If Me.PlanningGuideDataBindingSource.Position < 0 Then
            MsgBox("Keine Projektwahl") : Exit Sub
        End If
 
        'Aktuell ausgewähltes Projekt
        Dim row As DataRow = DirectCast(Me.PlanningGuideDataBindingSource( _
          Me.PlanningGuideDataBindingSource.Position), DataRowView).Row
        Dim projectid As Integer = CInt(row.Item("ID"))
        Dim rowindex As Integer = TimeTable_IndexOf(projectid)
 
        With timetable
            If rowindex = -1 Then
                'Keine offene Zeitmessung --> neue Messung starten
                .Rows.Add(.Rows.Count, projectid, Now, DBNull.Value, _
                  DBNull.Value)
            Else
                'vorhandene Zeitmessung abschließen
                .Rows(rowindex)("Ende") = Now
                Dim start As Date = DirectCast(.Rows(rowindex)("Start"), Date)
                Dim ende As Date = DirectCast(.Rows(rowindex)("Ende"), Date)
                .Rows(rowindex)("Intervall") = _
                    New TimeSpan(ende.Ticks - start.Ticks).TotalSeconds
                Hour_confirmation_quotationTextBox.Text = ende
            End If
        End With
        bsTime.ResetBindings(False)
 
        StartStopButtontext()
 
    End Sub
 
    Private Sub StartStopButtontext()
 
        If Me.PlanningGuideDataBindingSource.Position < 0 Then Exit Sub
 
        'Aktuell ausgewähltes Projekt
 
        Dim row As DataRow = DirectCast(Me.PlanningGuideDataBindingSource( _
          Me.PlanningGuideDataBindingSource.Position), DataRowView).Row
        Dim projectid As Integer = CInt(row.Item("ID"))
        Dim projectindex As Integer = TimeTable_IndexOf(projectid)
 
        If projectindex = -1 Then
            'Aktuell ist keine Messung für die Projektzeile gestartet
            Button_StartStop.Text = "Start  (" & CStr(projectid) & ")"
            Button_Reset.Enabled = False
        Else
            'Es läuft bereits eine Messung für die aktuelle Projektzeile
            Button_StartStop.Text = "Stop (" & CStr(projectid) & ")"
            Button_Reset.Enabled = True
        End If
 
    End Sub
 
    Private Sub Button_Reset_Click(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles Button_Reset.Click
 
        If Me.PlanningGuideDataBindingSource.Position < 0 Then Exit Sub
 
        'Aktuell ausgewähltes Projekt
        Dim row As DataRow = DirectCast(Me.PlanningGuideDataBindingSource( _
          Me.PlanningGuideDataBindingSource.Position), DataRowView).Row
        Dim projectid As Integer = CInt(row.Item("ID"))
        Dim projectindex As Integer = TimeTable_IndexOf(projectid)
 
        If projectindex = -1 Then Exit Sub
 
        timetable.Rows(projectindex)("Start") = Now 'Reset der Startzeit
 
    End Sub
 
    Private Function TimeTable_IndexOf(ByVal ProjectID As Integer) As Integer
 
        'Ermittlung des TimeTable-Index einer offenen Zeitmessung zur 
        'gegebenen ProjektID
        With timetable
            For i As Integer = 0 To .Rows.Count - 1
                If DirectCast(.Rows(i).Item("ProjectID"), Integer) = _
                    ProjectID AndAlso _
                    IsDBNull(.Rows(i).Item("Ende")) Then
                    Return i
                End If
            Next
        End With
        Return -1
 
    End Function
 
 
    Private Sub PlanningGuideDataDataGridView_SelectionChanged(ByVal sender As _
      Object, ByVal e As System.EventArgs) Handles _
      PlanningGuideDataDataGridView.SelectionChanged
        StartStopButtontext()
    End Sub