' Controls: 1 * Picturebox mit Bild eines Dartboards
Option Explicit
Private XM#, YM#, Rad#(5), Pi#
 
Private Sub Form_Load()
  ' Angaben in Pixeln
  Rad(0) = 200 ' Außenradius Double-Ring
  Rad(1) = 190 ' Innenradius Double-Ring
  Rad(2) = 100 ' Außenradius Triple-Ring
  Rad(3) = 90 ' Innenradius Triple-Ring
  Rad(4) = 20 ' Außenradius Bull
  Rad(5) = 10 ' Außenradius Bull's eye
  With Picture1
    .ScaleMode = vbPixels
    .AutoSize = True
    XM = .ScaleWidth \ 2 ' X-Position Mittelpunkt Dartboard
    YM = .ScaleHeight \ 2 ' Y-Position Mittelpunkt Dartboard
  End With
  Pi = Atn(1) * 4
End Sub
 
Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, X As _
  Single, Y As Single)
  Dim Radius#, DX#, DY#, Wnk#, Punkte&, Out$
 
  DX = X - XM
  DY = Y - YM
  Radius = Sqr(DX * DX + DY * DY)
  Select Case Radius
    Case Is <= Rad(5)
      Out = "Bull's eye"
      Punkte = 50
    Case Is <= Rad(4)
      Out = "Bull"
      Punkte = 25
    Case Is <= Rad(3)
      Punkte = 1
    Case Is <= Rad(2)
      Out = "Triple-Ring 3 *"
      Punkte = 1
    Case Is <= Rad(1)
      Punkte = 1
    Case Is <= Rad(0)
      Out = "Double-Ring 2 *"
      Punkte = 1
  End Select
  If Punkte = 1 Then
    Wnk = Atann(DX, DY) * 180 / Pi
    Punkte = Choose(20 - Int(((Wnk + 351) Mod 360) / 18), 6, 13, 4, 18, 1, 20, _
      5, 12, 9, 14, 11, 8, 16, 7, 19, 3, 17, 2, 15, 10)
  End If
  Me.Caption = Space$(20) & Out & " " & Punkte & " Punkt" & IIf(Punkte <> 1, _
    "e", "")
End Sub

Gruss,

Zardoz