Option Explicit
 
Const MyName As String = "cStringBuffer"
 
'*******************************************************************************
'******************               Interfaces               *********************
'*******************************************************************************
 
'*******************************************************************************
'******************           Constants, Types             *********************
'*******************************************************************************
Private Const c_InitialSize As Long = 32
 
 
'*******************************************************************************
'******************              Declaration               *********************
'*******************************************************************************
Private m_buffer As String
Private m_used As Long
Private m_allocated As Long
 
'*******************************************************************************
'******************                 Events                 *********************
'*******************************************************************************
 
'*******************************************************************************
'******************                 Class                  *********************
'*******************************************************************************
Private Sub Class_Initialize()
 
  Init
 
End Sub
 
 
'*******************************************************************************
'******************                Publics                 *********************
'*******************************************************************************
Public Sub Append(str As String)
 
  Dim Length As Long
  Dim requiredSize As Long
 
  'make sure the buffer is large enough and grow if necessary
  Length = Len(str)
  requiredSize = m_used + Length
  Do While requiredSize > m_allocated
    Grow
  Loop
 
  'insert new string into the buffer
  Mid$(m_buffer, m_used + 1) = str
  m_used = m_used + Length
End Sub
 
Public Sub AppendLine(Optional str As String = vbNullString)
 
  If Len(str) > 0 Then
    Append str
  End If
  Append vbNewLine
 
End Sub
 
Public Property Get Length() As Long
  Length = m_used
End Property
 
Public Property Get Result() As String
  Result = Left$(m_buffer, m_used)
End Property
 
Public Property Let Result(rhs As String)
  Init
  Append rhs
End Property
 
Public Sub Clear()
  Init
End Sub
 
'*******************************************************************************
'******************                Privates                *********************
'*******************************************************************************
Private Sub Init()
 
  m_buffer = String$(c_InitialSize, " ")
  m_allocated = c_InitialSize
  m_used = 0
 
End Sub
 
Private Sub Grow()
 
  m_buffer = m_buffer & String$(Len(m_buffer), " ")
  m_allocated = Len(m_buffer)
 
End Sub

Gruß
Dirk

--
?Get it right the first time