Public Class frmTreeViewDragDrop2
 
    Dim pNode As TreeNode
    Dim nd_lst As New List(Of String)
    Dim bs As New BindingSource With {.DataSource = nd_lst}
 
    Dim WithEvents treeview_explorer As New TreeView With {.Parent = Me}
    Dim WithEvents listbox_quotation As New ListBox With _
        {.Parent = Me, .Left = 200, .DataSource = bs, .AllowDrop = True}
 
    Const Extension As String = ".DOCX"
 
 
    Private Sub TreeView_Explorer_ItemDrag(sender As Object, _
      e As System.Windows.Forms.ItemDragEventArgs) _
       Handles TreeView_Explorer.ItemDrag
 
        If Not TypeOf e.Item Is TreeNode Then Exit Sub
 
        Dim nd As TreeNode = DirectCast(e.Item, TreeNode)
 
        If nd.Text.ToUpper.EndsWith(Extension) Then
            DoDragDrop(e.Item, DragDropEffects.Copy)
        Else
            For i As Integer = 0 To nd.Nodes.Count - 1
                If nd.Nodes(i).Text.ToUpper.EndsWith(Extension) Then
                    DoDragDrop(e.Item, DragDropEffects.Copy)
                    Exit Sub
                End If
            Next i
        End If
    End Sub
 
    Private Sub ListBox_Quotation_DragEnter(ByVal sender As Object, _
      ByVal e As System.Windows.Forms.DragEventArgs) _
      Handles ListBox_Quotation.DragEnter
 
        If e.Data.GetDataPresent(GetType(TreeNode).ToString, True) Then
            e.Effect = e.AllowedEffect
        Else
            e.Effect = DragDropEffects.None
        End If
 
    End Sub
 
 
    Private Sub ListBox_Quotation_DragDrop(ByVal sender As Object, _
         ByVal e As System.Windows.Forms.DragEventArgs) _
         Handles listbox_quotation.DragDrop
 
        Dim Nd As TreeNode = _
           DirectCast(e.Data.GetData(GetType(TreeNode)), TreeNode)
 
        If e.KeyState = 0 Then
 
            nd_lst.Clear()
 
            'nur linke Maustaste: Liste leeren und ggf. alle Subnodes eintragen
            If Nd.Text.ToUpper.EndsWith(Extension) Then
                If Nd.Parent Is Nothing Then Exit Sub
                Nd = Nd.Parent
            End If
 
            For Each sn As TreeNode In Nd.Nodes
                If sn.Text.ToUpper.EndsWith(Extension) Then
                    nd_lst.Add(Nd.Text & " --- " & sn.Text)
                End If
            Next sn       
 
        ElseIf e.KeyState = 8 Then
 
           'linke Maustaste und Shift-Taste: 
           'Liste bleibt, nur Subnode einfügen, falls noch nicht vorhanden
 
            If Nd.Text.ToUpper.EndsWith(Extension) Then
                Dim str As String = Nd.Parent.Text & " --- " & Nd.Text
                If Not nd_lst.Contains(str) Then nd_lst.Add(str)
            End If
        End If
 
        bs.ResetBindings(False)
 
    End Sub
 
 
 
    Private Sub frmTreeViewDragDrop2_Load(sender As Object, _
         e As System.EventArgs) Handles Me.Load
 
        With treeview_explorer
            Dim tnc As TreeNode = .Nodes.Add("Angebotsvorlage")
            Dim tnc2 As TreeNode = tnc.Nodes.Add("LP mit Greifer")
            tnc2.Nodes.Add("Anschreiben.docx")
            tnc2.Nodes.Add("Aufgabenstellung.docx")
            tnc2.Nodes.Add("System.docx")
            tnc2 = tnc.Nodes.Add("LP mit Drehantrieb")
            Dim tnc3 As TreeNode = tnc2.Nodes.Add("Subtyp 1")
            tnc3.Nodes.Add("Anschreiben.docx")
            tnc3.Nodes.Add("Aufgabenstellung.docx")
            tnc3.Nodes.Add("Vorlagen.docx")
        End With 
    End Sub
End Class