Public Class frmTreeNodeDragDrop
 
    Dim nd_lst As New List(Of String)
    Dim bs As New BindingSource With {.DataSource = nd_lst}
 
    Dim WithEvents trv As New TreeView With {.Parent = Me, .Width = 180}
 
    Dim WithEvents lbo As New ListBox With _
        {.Parent = Me, .Left = 200, .Width = 180, .DataSource = bs}
 
    Private Sub frmTreeNodeDragDrop_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
 
        Dim tnc As TreeNode = trv.Nodes.Add("EXCH-40")
        tnc.Nodes.Add("Anschreiben.doxc")
        tnc.Nodes.Add("Aufgabenstellung.doxc")
 
        tnc = trv.Nodes.Add("EXCH-60")
        tnc.Nodes.Add("Anschreiben.doxc")
        tnc.Nodes.Add("Aufgabenstellung.doxc")
 
        lbo.AllowDrop = True
    End Sub
 
 
    Private Sub trv_ItemDrag(sender As Object, e As  _
         System.Windows.Forms.ItemDragEventArgs) Handles trv.ItemDrag
 
        DoDragDrop(e.Item, DragDropEffects.Copy)
 
    End Sub
 
 
 
    Private Sub Lbo_DragEnter(ByVal sender As Object, ByVal e As  _
          System.Windows.Forms.DragEventArgs) Handles lbo.DragEnter
 
        If e.Data.GetDataPresent(GetType(TreeNode).ToString, True) Then
            e.Effect = e.AllowedEffect
        Else
            e.Effect = DragDropEffects.None
        End If
    End Sub
 
 
 
    Private Sub lbo_DragDrop(ByVal sender As Object, ByVal e As  _
         System.Windows.Forms.DragEventArgs) Handles lbo.DragDrop
 
 
        Dim Nd As TreeNode = _
        DirectCast(e.Data.GetData(GetType(TreeNode)), TreeNode)
 
        If Nd.Parent IsNot Nothing Then Nd = Nd.Parent
 
        nd_lst.Clear()
        nd_lst.Add(Nd.Text) 
 
        nd_lst.AddRange((From sn As Object In Nd.Nodes _
                   Select Nd.Text & " --- " & _
                   DirectCast(sn, TreeNode).Text).AsEnumerable)
 
        bs.ResetBindings(False)
 
    End Sub
 
End Class