Public Class Form1
	Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As _
  System.EventArgs) Handles Button1.Click
		Try
			Dim birthDay As New DateTime(1968, 2, 29) '1968 war ein Schaltjahr
			Dim age As Integer = Now.GetAge(birthDay)
			'Bei VS 2005: Dim age As Integer = GetAge(Now, birthDay)
			Debug.WriteLine("Age is " & age)
		Catch ex As Exception
			MsgBox(ex.ToString)
		End Try
	End Sub
End Class
 
Module Extensions
 
	'Bei Visual Studio 2005 <System.Runtime.CompilerServices.Extension()> weglassen
	<System.Runtime.CompilerServices.Extension()> _
	Public Function GetAge(ByVal referenceDate As DateTime, ByVal birthDate As _
DateTime) As Integer
		birthDate = birthDate.Date
		referenceDate = referenceDate.Date
 
		If referenceDate < birthDate Then
			Throw New ArgumentException("The birthdate's date must not be smaller than" & _
  "the reference date's date.")
		End If
 
		Dim age As Integer = referenceDate.Year - birthDate.Year
 
		'Überprüfen, ob weniger als ein volles Jahr abgelaufen ist. Falls ja: Ein 
' Jahr abziehen
		Dim compareDate As DateTime
		If Not DateTime.IsLeapYear(referenceDate.Year) AndAlso birthDate.Month = 2 _
  AndAlso birthDate.Day = 29 Then
			compareDate = New DateTime(referenceDate.Year, 3, 1)
			'oder: compareDate = New DateTime(referenceDate.Year, 2, 28)
		Else
			compareDate = New DateTime(referenceDate.Year, birthDate.Month, _
  birthDate.Day)
		End If
 
		Dim sp As TimeSpan = referenceDate - compareDate
		If sp < TimeSpan.Zero Then
			age -= 1
		End If
		Return age
	End Function
 
End Module