Private Function GetUTC(ByVal sTimeServer As String) As Date
        ' Standard-Rückgabewert bei Fehler
        Dim vDate As Date = Nothing
 
        Try
            ' Verbindung zum TimerServer herstellen
            Dim oClient As TcpClient = New TcpClient()
            oClient.Connect(sTimeServer, 13)
 
            ' NetworkStream-Objekt für die Antwort
            Dim oStream As NetworkStream = oClient.GetStream()
 
            ' Antwort des TimeServer lesen
            Dim cCh1 As Char
            Dim sResponse As New StringBuilder
            Dim nByte As Integer
 
            ' solange byteweise einlesen, bis keine 
            ' Daten mehr vom Server zurückkommen
            Do
                nByte = oStream.ReadByte()
                If nByte = -1 Then Exit Do
                cCh1 = System.Convert.ToChar(nByte)
                sResponse.Append(cCh1.ToString)
            Loop Until nByte = 13
 
            ' Verbindung trennen
            oClient.Close()
 
            If sResponse.Length > 0 Then
                Dim sBuffer As String = sResponse.ToString
 
                ' Atomzeiten werden in folgendem Format übermitteln:
                ' xxxxx yy-mm-dd hh:mm:ss xx x x  xx.x UTC(NIST) *
 
                ' Datum und Uhrzeit aus dem Rückgabestring des 
                ' TimeServers extahieren
                If sBuffer.Contains(" ") Then
                    Dim sData() As String = sBuffer.Split(" "c)
                    If sData(1).Length = 8 AndAlso sData(2).Length = 8 Then
                        ' Datumsangabe in Einzelteile splitten
                        Dim sDate() As String = Split(sData(1), "-")
 
                        ' Uhrzeitangabe in Einzelteile splitten
                        Dim sTime() As String = Split(sData(2), ":")
 
                        ' einzelne Datumswerte und Uhrzeitwerte zu neuem 
                        ' Date-Objekt zusammenstellen
                        vDate = New DateTime(2000 + CInt(sDate(0)), _
                          CInt(sDate(1)), CInt(sDate(2)), _
                          CInt(sTime(0)), CInt(sTime(1)), _
                          CInt(sTime(2)), DateTimeKind.Utc)
 
                    End If
                End If
            End If
        Catch ex As Exception
            vDate = Nothing
        End Try
 
        Return vDate
    End Function

        Dim UTC As Date = GetUTC("time-a.nist.gov")
        If Not UTC = Nothing Then
            MsgBox("Die aktuelle UTC ist: " & UTC)
 
        Else
            MsgBox("Atomzeit konnte nicht ermittelt werden!")
        End If
 
        For Each TZI As TimeZoneInfo In TimeZoneInfo.GetSystemTimeZones
 
            Dim LVI As New ListViewItem
 
            LVI.Text = TZI.Id
            LVI.SubItems.Add(TZI.DisplayName)
 
            Dim localTime As Date = TimeZoneInfo.ConvertTimeFromUtc(UTC, TZI)
            LVI.SubItems.Add(localTime.ToLongDateString & " " & _
              localTime.ToLongTimeString)
 
            ListView1.Items.Add(LVI)
        Next
 
        Dim CaliforniaTimeZone As TimeZoneInfo = _
            TimeZoneInfo.FindSystemTimeZoneById("Pacific Standard Time")
 
        Dim CaliforniaTime As Date = _
            TimeZoneInfo.ConvertTimeFromUtc(UTC, CaliforniaTimeZone)
 
        MessageBox.Show("In Kalifornien ist es: " & _
          CaliforniaTime.ToLongTimeString)