Public Class Form1
    Private WithEvents Pb As New PictureBox
    Dim r(3) As Rectangle
    Dim run(3) As Boolean
    Dim ic() As Icon = {SystemIcons.Error, SystemIcons.Warning, _
      SystemIcons.Question, SystemIcons.Shield}
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles MyBase.Load
        Me.Controls.Add(Pb)
        Pb.SetBounds(5, 5, Me.Width - 15, Me.Height - 35)
        Pb.BackColor = Color.Black
        For i As Int32 = 0 To 3
            r(i) = New Rectangle(70 + i * 40, 120, 32, 32)
        Next
    End Sub
 
    Private Sub Pb_MouseDown(ByVal sender As Object, ByVal e As _
      System.Windows.Forms.MouseEventArgs) Handles Pb.MouseDown
        For i As Int32 = 0 To 3
            If r(i).Contains(e.Location) Then run(i) = True
        Next
    End Sub
 
    Private Sub Pb_MouseUp(ByVal sender As Object, ByVal e As _
      System.Windows.Forms.MouseEventArgs) Handles Pb.MouseUp
        For i As Int32 = 0 To 3
            run(i) = False
        Next
    End Sub
    Private Sub Pb_MouseMove(ByVal sender As Object, ByVal e As _
      System.Windows.Forms.MouseEventArgs) Handles Pb.MouseMove
        Dim re As New Rectangle(Pb.Location, Pb.Size)
        For i As Int32 = 0 To 3
            If run(i) AndAlso re.Contains(e.Location) Then
                r(i).X = e.X - r(i).Width \ 2
                r(i).Y = e.Y - r(i).Height \ 2
                Pb.Invalidate()
                Exit Sub
            End If
        Next
    End Sub
 
    Private Sub Pb_Paint(ByVal sender As Object, ByVal e As _
      System.Windows.Forms.PaintEventArgs) Handles Pb.Paint
        With e.Graphics
            .SmoothingMode = Drawing2D.SmoothingMode.AntiAlias
            .DrawLine(Pens.White, 0, 0, Pb.Width, Pb.Height)
            .DrawLine(Pens.White, 0, Pb.Height, Pb.Width, 0)
            For i As Int32 = 0 To 3
                .DrawIcon(ic(i), r(i))
            Next
        End With
    End Sub
End Class