Kalenderwoche korrekt ermitteln Leider funktioniert die Format-Funktion von VB in Bezug auf das Ermitteln der Kalenderwoche nicht korrekt. Dieser Tipp schafft Abhilfe.
Autor:   André Gerards	Bewertung:     [ Jetzt bewerten ]	Views:  28.822
ohne Homepage	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 53 Bewertung insgesamt: gut Durchschnittliche Bewertung: 4.1 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Wie ermittelt man die Kalenderwoche eines beliebigen Datums? Wenn man der VB-Hilfe Glauben schenkt, sollte dies mit der Format-Funktion ein Leichtes sein:

Dim nWeek As Integer
nWeek = Format$(vDate, "ww", vbMonday, vbFirstFourDays)

Im ersten Moment scheint es so, als würde die Kalenderwoche korrekt ermittelt werden:

' Beispiel: 22.03.04
nWeek = Format$(DateSerial(2004, 3, 22), "ww", vbMonday, vbFirstFourDays)
MsgBox CStr(nWeek)  ' ' Ergebnis: 13 - KORREKT!

' Beispiel: 31.12.07
nWeek = Format$(DateSerial(2007, 12, 31), "ww", vbMonday, vbFirstFourDays)
MsgBox CStr(nWeek)  ' ' Ergebnis: 53 - FALSCH! Korrekt wäre 1!!!

' Beispiel: 29.12.03
nWeek = Format$(DateSerial(2003, 12, 29), "ww", vbMonday, vbFirstFourDays)
MsgBox CStr(nWeek)  ' ' Ergebnis: 53 - FALSCH! Korrekt wäre 1!!!

Fazit:
Solange es sich bei dem Datum nicht um die letzte Woche eines Jahres handelt, gibt die Format-Funktion die korrekten Kalenderwoche zurück.

Nachfolgender Tipp errechnet die Kalenderwoche auch dann korrekt, wenn es sich um die letzte Woche eines Kalenderjahres handelt.

Das Problem wird umgangen, indem man das Datum des Dienstags in dieser Woche ermittle (also losgelöst vom Montag und vom Jahresletzten) und daran die Datepart-Funktion ausführt. Dann klappt's und das Ergebnis muss ggf. nur noch auf die jeweilige Wochendarstellung zurückgerechnet werden.

' *** Ermittelt die Kalenderwoche mit dem zur Kalenderwoche gehörigem Jahr
' *** fConvKW wird in der Form YYYYWW zurückgegeben ***
Public Function fConvKW(ByVal ZuKonvertDat As Date) As String
  ' PROBLEM:
  ' DatePart - in der uns üblichen Arbeitsweise 
  ' DatePart("ww", Datum, vbMonday, vbFirstFourDays) -
  ' wirft für folgende Daten folgende Werte aus
  ' So, 28.12.2003 oder 30.12.2007 -> KW52 -> richtig
  ' Mo, 29.12.2003 oder 31.12.2007 -> KW53 -> QUATSCH
  ' Di, 30.12.2003 oder 01.01.2008 -> KW01 -> richtig
  ' deshalb bestimme ich vorsichtshalber die Kalenderwoche 
  ' des Dienstags ?!?!?!?!?!
 
  If Weekday(ZuKonvertDat) = vbMonday Then _
    ZuKonvertDat = ZuKonvertDat + 1
 
  fConvKW = DatePart("ww", ZuKonvertDat, vbMonday, vbFirstFourDays)
 
  ' Anpassung des Jahres und Ergänzung der Null
  ' (in den Kalenderwochen 01, 52 und 53 kann das Jahr des Datums 
  ' anders sein als das Jahr der zugehörigen Kalenderwoche.
  ' So liegt der 31.12.2001 in KW01/2002)
 
  If fConvKW < 10 Then
    fConvKW = Year(ZuKonvertDat + 6) & "0" & fConvKW
  Else
    fConvKW = Year(ZuKonvertDat - 6) & fConvKW
  End If
End Function

Beispiel:

' Beispiel: 29.12.03
Dim sKW As String
sKW = fConvKW(CDate("29.12.03"))
MsgBox Right$(sKW, 2) & "/" & Left$(sKW, 4) ' ' Ergebnis: 01/2004 - KORREKT!