Telefonnummer über die Wählhilfe wählen Ein Beispiel, wie sich eine beliebige Telefonnummer unter Zuhilfenahme der Windows-Wählhilfe wählen lässt.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  29.072
https://www.tools4vb.com	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 22 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.7 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Ist auf dem Anwendersystem die Windows-Wählhilfe installiert, lässt sich eine Rufnummer aus der eigenen VB-Anwendung ganz leicht wählen. Hierzu bedienen wir uns einfach der TAPI-Funktion tapiRequestMakeCall. TAPI steht für Telephony Application Programming Interface.

' Benötigte API-Deklaration
Private Declare Function tapiRequestMakeCall Lib "tapi32.dll" ( _
  ByVal lpszDestAddress As String, _
  ByVal lpszAppName As String, _
  ByVal lpszCalledParty As String, _
  ByVal lpszComment As String) As Long
 
Private Const TAPIERR_NOREQUESTRECIPIENT = -2&
Private Const TAPIERR_REQUESTQUEUEFULL = -3&
Private Const TAPIERR_INVALDESTADDRESS = -4&

Die nachfolgende Funktion versucht die Windows-Wählhilfe zu starten und die angegebene Rufnummer zu wählen. Als weitere optionale Parameter können Sie noch den Teilnehmer (Namen), sowie eine Bemerkung (Grund des Anrufs) angeben.

' Windows-Wählhilfe starten und Telefonnummer wählen
Public Sub Dial(ByVal sPhoneNumber As String, _
  ByVal sRecipient As String, _
  Optional ByVal sComment As String = "")
 
  Dim sBuffer As String
  Dim nResult As Long
 
  ' Wählhilfe starten und Telefonnummer wählen
  nResult = tapiRequestMakeCall(sPhoneNumber, _
    App.ProductName, sRecipient, sComment)
 
  ' Rückgabewert auswerten
  If nResult <> 0 Then
    ' Fehler!
    Select Case nResult
      Case TAPIERR_NOREQUESTRECIPIENT
        MsgBox "Diw Windows Wählhilfe ist nicht installiert" & _
          " oder konnte nicht gestartet werden!"
 
      Case TAPIERR_REQUESTQUEUEFULL
        MsgBox "Die Anrufschlange ist voll!"
 
      Case TAPIERR_INVALDESTADDRESS
        MsgBox "Ungültige Telefonnummer!"
 
      Case Else
        MsgBox "Sonstiger Fehler!"
 
    End Select
  End If
End Sub

Beispiel:

Dial "12345", "Herrn Huber", "privat"