Datenbanken und Passwörter (DAO) Beispiele, wie man Access-Datenbanken beim Erstellen oder nachsträglich durch ein Passwort schützen kann.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  42.233
https://www.tools4vb.com	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	kein Beispielprojekt

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 99 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.8 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Die nachfolgenden Beispiele zeigen, wie Sie eine Access-Datenbank durch ein Passwort schützen können, sei es beim Erstellen der Datenbank oder nachträglich. Weiterhin erfahren Sie, wie Sie passwortgeschütze Datenbank wieder öffnen oder ein vorhandenes Passwort vollständig wieder entfernen können.

Der Reihe nach...

Neue Datenbank mit Passwort erstellen
Das Erstellen einer neuen Datenbank inkl. Passwort geht so:

' Neue Datenbank mit Passwort
Dim DB As Database
Dim sMDBFile as String
Dim sPasswort As String
 
sMDBFile = App.Path & "\MeineDB.MDB"
sPasswort = "geheim"
 
Set DB = DBEngine.CreateDatabase(sMDBFile, dbLangGeneral & _
  ";pwd=" & sPasswort, dbEncrypt)

Passwort nachträglich festlegen
Existiert die Access-Datenbank bereits, so lässt sich ein Passwort auch nachträglich noch festlegen.

' Datenbank nachträglich durch Passwort schützen
Dim DB As Database
Dim sMDBFile As String
Dim sPasswort As String
 
sMDBFile = App.Path & "\MeineDB.MDB"
sPasswort = "geheim"
 
' Datenbank EXKLUSIV öffnen
Set DB = DBEngine.OpenDatabase(sMDBFile, True, False)
 
' Passwort festlegen
DB.NewPassword "", sPasswort
 
' Datenbank schliessen
DB.Close

Bestehendes Passwort ändern
Ein bereits vorhandenes Passwort kann natürlich jederzeit auch wieder geändert werden.

' DB-Passwort ändern
Dim DB As Database
Dim sMDBFile As String
Dim sPasswortAlt As String
Dim sPasswortNeu As String
 
sMDBFile = App.Path & "\MeineDB.MDB"
sPasswortAlt = "geheim"
sPasswortNeu = "geheimer"
 
' Datenbank EXKLUSIV öffnen
Set DB = DBEngine.OpenDatabase(sMDBFile, True, False, _
  ";pwd=" & sPasswortAlt)
 
' Passwort ändern
DB.NewPassword sPasswortAlt, sPasswortNeu
 
' Datenbank schliessen
DB.Close

Passwort löschen
Und wenn man ein vorhandenes Passwort gänzlich wieder entfernen will - na wie wird's wohl gehen? Genau!

' DB-Passwort entfernen
Dim DB As Database
Dim sMDBFile As String
Dim sPasswort As String
 
sMDBFile = App.Path & "\MeineDB.MDB"
sPasswort = "geheimer"
 
' Datenbank EXKLUSIV öffnen
Set DB = DBEngine.OpenDatabase(sMDBFile, True, False, _
  ";pwd=" & sPasswort)
 
' Passwort entfernen
DB.NewPassword sPasswort, ""
 
' Datenbank schliessen
DB.Close

Was fehlt jetzt noch? Genau! Das Öffnen einer passwortschützen Datenbank.
Und das geht so:

' Passwortgeschütze Datenbank öffnen
Dim DB As Database
Dim sMDBFile As String
Dim sPasswort As String
 
sMDBFile = App.Path & "\MeineDB.MDB"
sPasswort = "geheimer"
 
Set DB = DBEngine.OpenDatabase(sMDBFile, False, False, _
  ";pwd=" & sPasswort)

Und falls Sie das Data-Control verwenden...
muss das Passwort in der Connect-Eigenschaft angegeben werden:

' passwortgeschütze Datenbank via Data-Control ansprechen
Dim sMDBFile As String
Dim sPasswort As String
 
sMDBFile = App.Path & "\MeineDB.MDB"
sPasswort = "geheimer"
 
Data1.DatabaseName = sMDBFile
Data1.Connect = ";pwd=" & sPasswort

ABER VORSICHT!
Zum Öffnen einer passwortgeschützten Datenbank brauchen Sie unbedingt das korrekte Passwort - sonst sehen Sie alt aus, bzw. Ihre Daten!