Weiche Zeilenumbrüche umwandeln Eine Funktion, welche alle weichen Zeilenumbrüche einer TextBox in harte Zeilenumbrüche (vbCrLf) umwandelt.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  19.568
https://www.tools4vb.com	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 10 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.9 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Die nachfolgende Funktion wandelt alle weichen Zeilenumbrüche einer MultiLine-TextBox in harte Zeilenumbrüche (vbCrLf) um. Von weichen Zeilenumbrüchen spricht man, wenn der Text beim Erreichen des rechten Textrands automatisch in die nachfolgende Zeile umgebrochen wird.

Möchte man z.B. den Text genau so ausdrucken, wie er im Text-Eingabefeld dargestellt wird, so müssen demnach alle weichen Zeilenumbrüche in harte Zeilenumbrüche umgewandelt werden.

Die nachfolgende Funktion erwartet als Parameter ein TextBox-Control und gibt den modfizierten Text als String zurück.

' zunächst die benötigten API-Deklarationen
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  ByVal lParam As Any) As Long 
 
Private Const EM_GETLINE = &HC4 
Private Const EM_GETLINECOUNT = &HBA

' Weiche Umbrüche in harte Zeilenumbrüche umwandeln
Public Function DoTextCrLf(TextBox As TextBox) _
  As String 
 
  Dim I As Long 
  Dim lngLineCount As Long 
  Dim lngLineLength As Long 
  Dim strLine As String 
 
  ' zunächst die Anzahl der Zeilen ermitteln
  lngLineCount = SendMessage(TextBox.hwnd, _ 
    EM_GETLINECOUNT, 0, 0&) 
 
  ' jetzt die einzelnen Zeilen ermitteln
  For I = 0 To lngLineCount - 1 
    strLine = Space$(1024) 
 
    lngLineLength = SendMessage(TextBox.hwnd, _ 
      EM_GETLINE, I, strLine) 
 
    DoTextCrLf = DoTextCrLf + _ 
      Left$(strLine, lngLineLength) + _ 
      IIf(I < lngLineCount - 1, vbCrLf, "") 
  Next I 
End Function