Public Function DBInsert(ByVal vstrTable As String, ByVal vstrKey As String, _
  ByRef vrefFields As Variant, ByRef vrefValues As Variant)
'Datensatz einfügen
 
Dim strSQL As String
Dim connData As ADODB.Connection
Dim rstData As ADODB.Recordset
Dim intCounter As Integer
 
    On Error GoTo err_Handler
 
    'Leerstrings in Null konvertieren:
    If IsArray(vrefValues) Then
        For intCounter = LBound(vrefValues) To UBound(vrefValues)
            If vrefValues(intCounter) = vbNullString Then
                vrefValues(intCounter) = Null
            End If
        Next intCounter
    Else
        If vrefValues = vbNullString Then
            vrefValues = Null
        End If
    End If
 
    '0 Datensätze holen...
    Set connData = New ADODB.Connection
    connData.Open mstrDBConnect
 
    strSQL = "SELECT * FROM " & vstrTable & " WHERE 1=0"
    Set rstData = New ADODB.Recordset
 
    rstData.Open strSQL, connData, adOpenKeyset, adLockOptimistic
    rstData.AddNew vrefFields, vrefValues
    DBInsert = rstData(vstrKey)
 
    rstData.Close
    connData.Close
 
    Set rstData = Nothing
    Set connData = Nothing
 
    Exit Function
 
err_Handler:
 
    Select Case Err.Number
        Case Else
            ErrorLog "modADO.DBInsert", Err.Number, Err.Description, Err.Source
            Set rstData = Nothing
            Exit Function
    End Select
 
End Function