Option Explicit
 
' die benötigte API-Funktion, um die Schnittstelleninformationen abzurufen
Private Declare Function GetDefaultCommConfig Lib "kernel32" _
  Alias "GetDefaultCommConfigA" (ByVal lpszName As String, lpCC As COMMCONFIG, _
  lpdwSize As Long) As Long
 
' Device Control Block-Struktur
' bestimmt alle möglichen Einstellungen für einen Kommunikationskanal
' (für weitergehende Informationen zu dieser Struktur siehe MSDN-Hilfe)
Private Type DCB
    DCBlength As Long
    BaudRate As Long
    fBitFields As Long
    wReserved As Integer
    XonLim As Integer
    XoffLim As Integer
    ByteSize As Byte
    Parity As Byte
    StopBits As Byte
    XonChar As Byte
    XoffChar As Byte
    ErrorChar As Byte
    EofChar As Byte
    EvtChar As Byte
    wReserved1 As Integer
End Type
 
' bestimmt den Konfigurations-Status eines Kommunikationskanals
Private Type COMMCONFIG
    dwSize As Long
    wVersion As Integer
    wReserved As Integer
    dcbx As DCB
    dwProviderSubType As Long
    dwProviderOffset As Long
    dwProviderSize As Long
    wcProviderData As Byte
End Type
 
Private Function ExistiertComPort(ByVal ComPort As Integer) As Boolean
 
    Dim ccComConfig As COMMCONFIG
    Dim lCCGroesse As Long
    Dim lReturn As Long
 
    ' benötigten Speicherplatz der COMMCONFIG-Struktur bestimmen
    lCCGroesse = LenB(ccComConfig)
    ' versuche die Defaulteinstellungen des Ports zu lesen ...
    ' bei Fehlschlag wird NULL zurückgegeben -> Port existiert nicht
    lReturn = GetDefaultCommConfig("COM" + Trim(Str(ComPort)) + Chr(0), _
      ccComConfig, lCCGroesse)
    ExistiertComPort = lReturn <> 0
 
End Function