Private Declare Function GetBitmapBits Lib "gdi32" (ByVal hBitmap As Long, _
  ByVal dwCount As Long, lpBits As Any) As Long
Private Declare Function SetBitmapBits Lib "gdi32" (ByVal hBitmap As Long, _
ByVal dwCount As Long, lpBits As Any) As Long
 
Private Sub Command1_Click()
 
  Dim i&, j&, SW&, SH&, ByteCnt&, ByteMap() As Byte
  Dim BpP&, Zeile&, Grenzwert&
 
  Grenzwert = 128
  BpP = 4 ' Bytes pro Pixel (Grafikkarte)
  With Picture1
    .ScaleMode = vbPixels
    .AutoRedraw = True
    SW = .ScaleWidth
    SH = .ScaleHeight
    Zeile = SW * BpP
    If (Zeile Mod 4) <> 0 Then
      Zeile = Zeile + (4 - (Zeile Mod 4))
    End If
    ByteCnt = Zeile * SH
    ReDim ByteMap(ByteCnt - 1)
    Call GetBitmapBits(.Image.Handle, ByteCnt, ByteMap(0))
    For j = 0 To Zeile * (SH - 1) Step Zeile
      For i = j To j + BpP * (SW - 1) Step BpP
        If ByteMap(i) < Grenzwert And ByteMap(i + 1) < Grenzwert And ByteMap(i _
          + 2) < Grenzwert Then
          ByteMap(i) = 0
          ByteMap(i + 1) = 0
          ByteMap(i + 2) = 0
        End If
      Next i
    Next j
    Call SetBitmapBits(.Image.Handle, ByteCnt, ByteMap(0))
    .Refresh
  End With
  Erase ByteMap
 
End Sub

Gruss,

Zardoz