' Copyright © 2007 by Zardoz
' Controls: 1 * Picturebox
Option Explicit
 
Private Type PointAPI
  x As Long
  y As Long
End Type
 
Private Declare Function CreatePolygonRgn Lib "gdi32" (lpPoint As PointAPI, _
  ByVal nCount As Long, ByVal nPolyFillMode As Long) As Long
Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As _
Long
Private Declare Function PaintRgn Lib "gdi32" (ByVal hdc As Long, ByVal hRgn As _
Long) As Long
 
Private Const ALTERNATE& = 1
Private Const Pi! = 3.14159265358979
 
Private Sub Form_Activate()
 
With Picture1
  .ScaleMode = vbPixels
  .AutoRedraw = True
  .BackColor = vbBlue
  .FillColor = vbYellow
  .FillStyle = vbFSSolid
  .Move 0, 0, Me.ScaleWidth, Me.ScaleHeight
End With
DoEvents
Call RotateRoundRect(100, 100, 200, 150, 30, 35)
 
End Sub
 
Private Sub RotateRoundRect(XPos!, YPos!, Breite!, Hoehe!, Radius!, Winkel!) ' 
' Winkel in Altgrad
 
Dim CosW!, SinW!, XP!, YP!, i%, j%, N%, Z%, Wnk!, Rgn1&, Figur() As PointAPI
 
Wnk = Winkel * Pi / 180
SinW = Sin(Wnk)
CosW = Cos(Wnk)
N = Pi * Radius / 2
ReDim Figur(4 * N - 1)
Z = 0
For i = 0 To 3
  For j = N - 1 To 0 Step -1
    Wnk = Pi / 2 * (1 + j / N - i)
    XP = Radius * (1 + Cos(Wnk)) + Breite * (((i \ 2) Xor (i And 1)) - 0.5)
    YP = Radius * (1 - Sin(Wnk)) + Hoehe * ((i \ 2) - 0.5)
    Figur(Z).x = CosW * XP - SinW * YP + XPos + Breite / 2
    Figur(Z).y = SinW * XP + CosW * YP + YPos + Hoehe / 2
    Z = Z + 1
  Next j
Next i
Rgn1 = CreatePolygonRgn(Figur(0), 4 * N, ALTERNATE)
Call PaintRgn(Picture1.hdc, Rgn1)
Call DeleteObject(Rgn1)
Picture1.Refresh
 
End Sub

Gruss,

Zardoz