'------------------------------------------------------
' Wandelt String in RTF-Sequenz
'------------------------------------------------------
Function RtfContent(strFileContent As String) As String
 
    Dim strTxt As String
    Dim strRtf As String
    Dim i As Integer
    Dim ch As String
    Dim CharCode As Integer
 
    strTxt = strFileContent
    If CBool(InStr(strTxt, "\")) Then _
        strTxt = Replace(strTxt, "\", "\\") 'RTF-Steuerzeichen \ ersetzen
    If CBool(InStr(strTxt, "{")) Then _
        strTxt = Replace(strTxt, "{", "\{") 'RTF-Steuerzeichen { ersetzen
    If CBool(InStr(strTxt, "}")) Then _
        strTxt = Replace(strTxt, "}", "\}") 'RTF-Steuerzeichen } ersetzen
 
    strRtf = "{\rtf1\ansi\ansicpg1252{" 'RTF-Start, Codepage 1252 einstellen
    For i = 1 To Len(strTxt)
        ch = Mid(strTxt, i, 1) 'Zeichen
        CharCode = Asc(ch) 'Zeichencode (0 bis 255)
        If CharCode < 32 Then
            'Steuerzeichen
            strRtf = strRtf & Chr$(CharCode)
            If CharCode = 10 Then strRtf = strRtf & "\par " 'Zeilenumbruch
        ElseIf CharCode < 128 Then
            'Standardzeichen
            strRtf = strRtf & ch
        Else
            'Sonderzeichen
            strRtf = strRtf & "\'" & Right("00" & Hex(CharCode), 2)
        End If
    Next i
    strRtf = strRtf & "}}" 'RTF-Abschluss
 
    RtfContent = strRtf
 
End Function
 
 
Sub OpenFile(PathAndFilename As String)
 
    Dim strFileContent As String
    Dim strRtfContent As String
    Dim FileNr1 As Long
 
    FileNr1 = FreeFile
    Open PathAndFilename For Input As #FileNr1
 
    strFileContent = Input(LOF(FileNr1), FileNr1)
    strRtfContent = RtfContent(strFileContent)
    RichTextBox1.TextRTF = strRtfContent
 
End Sub

Ciao,
Manfred Becker