Public Sub AddLVItemToTable(oLSV As MSComctlLib.ListView, _
                            oItem As ListItem, _
                            sDB_Path As String, _
                            sTable As String)
  '--------------------------------------------------
  ' oLSV        - Das ListView, aus dem das ListItem kommt
  ' oItem       - Das Item, welches in die Datenank soll
  ' sDB_Path    - Pfad & Name der Access DB
  ' sTable      - Name der Tabelle, in die das Item soll
  '--------------------------------------------------
  On Error GoTo Error_
  Dim oCon          As New ADODB.Connection
  Dim oCommand      As New ADODB.Command
  Dim i             As Long
  Dim sSQL          As String
  Dim sHeader       As String
  Dim sValues       As String
  '--------------------------------------------------
  ' Eine Connectionzu der Datenbank aufbauen
  With oCon ' Die Connection zur Datenbank
    .Provider = "Microsoft.Jet.OLEDB.3.51"
    .Mode = adModeReadWrite
    .Open sDB_Path
    '.CursorLocation = adUseClient
  End With
  '--------------------------------------------------
  ' SQL String für den Input aufbauen
  sSQL = "INSERT INTO " & sTable & " ("
  sHeader = oLSV.ColumnHeaders(2).Key
  sValues = "'" & oItem.SubItems(1) & "'"
  For i = 3 To oLSV.ColumnHeaders.Count
    ' Die erste Spalte enhält einen AutoWert, deshalb ignorieren
    If oItem.SubItems(i - 1) <> "" Then
      ' SubItem nur berücksichtigen, wenn es auch einen Wert enthält
      sHeader = sHeader & ", " & oLSV.ColumnHeaders(i).Key
      sValues = sValues & ", '" & oItem.SubItems(i - 1) & "'"
    End If
  Next i
  sSQL = sSQL & sHeader & ") VALUES (" & sValues & ")"
  '--------------------------------------------------
  ' Nun in die Datenbank eintragen
  Set oCommand = New ADODB.Command
  With oCommand
    .ActiveConnection = oCon
    .CommandText = sSQL
    .Execute
  End With
 
  Set oCon = Nothing
  Set oCommand = Nothing
  Exit Sub
  '--------------------------------------------------
Error_:
  Debug.Print Err.Number
  Debug.Print Err.Description
  Set oCon = Nothing
  Set oCommand = Nothing
End Sub