Private Sub Kalender()
  Dim xTag%, xMonat%, xJahr%, xWochentag%, xTageImMonat%
  Dim Datum1 As Date, Tag1 As Integer
  Dim i%, pos%
  Const Abstand% = 4 * 15 'Abstand = 4 Pixel (in Twips)
 
  xTag = Day(Date): xMonat = Month(Date): xJahr = Year(Date)
  xWochentag = Weekday(Date, vbUseSystemDayOfWeek)
  xTageImMonat = Day(DateSerial(xJahr, xMonat + 1, 0))
 
  Datum1 = DateSerial(xJahr, xMonat, 1)
  Tag1 = Weekday(Datum1, vbUseSystemDayOfWeek)
 
  'Monatsnamen
  For i = 0 To 11
    If i > 0 Then Load LblMonat(i)
    With LblMonat(i)
      .Left = LblMonat(0).Left
      .Top = LblMonat(0).Top + (.Height + Abstand) * i
      .Caption = MonthName(i + 1)
      .Alignment = 2
      .Visible = True
    End With
  Next
 
  'Wochentagsnamen
  For i = 0 To 6
    If i > 0 Then Load LblTagName(i)
    With LblTagName(i)
      .Left = LblTagName(0).Left + (.Width + Abstand) * i
      .Caption = WeekdayName(i + 1)
      .Alignment = 2
      .Visible = True
    End With
  Next
 
  'Tage
  For i = 0 To xTageImMonat - 1
    If i > 0 Then Load LblDatum(i)
    pos = i + Tag1 - 1 'Position der Tage
    With LblDatum(i)
      .Left = LblTagName(0).Left + (.Width + Abstand) * (pos Mod 7)
      .Top = LblDatum(0).Top + (.Height + Abstand) * (pos \ 7)
      .Caption = i + 1
      .Alignment = 2
      .Visible = True
      End With
    Next
 
  'Markieren
  LblDatum(xTag - 1).ForeColor = vbRed
  LblMonat(xMonat - 1).ForeColor = vbRed
  LblTagName(xWochentag - 1).ForeColor = vbRed
End Sub