'Form1
Option Explicit
 
'untergeordnete Instanzen von Form2
Dim WithEvents f2 As Form2
Dim WithEvents f3 As Form2
 
Private Sub Form_Load()
 
   Set f2 = New Form2
   Set f3 = New Form2
   Me.Show
 
   f2.Top = Me.Top + 400: f2.Left = Me.Left + 400
   f2.Show
   f2.ZOrder 0
 
   f3.Top = Me.Top + 800: f3.Left = Me.Left + 800
   f3.Show
   f3.ZOrder 0
End Sub
 
Public Sub HideSubWindows(Optional ByVal minimize As Boolean = True)
    f2.Hide: f3.Hide
    If Me.WindowState <> vbMinimized And minimize Then _
       Me.WindowState = vbMinimized
End Sub
 
Public Sub ShowSubWindows()
    f2.WindowState = vbNormal: f3.WindowState = vbNormal
    f2.Show: f3.Show
End Sub
 
'Benachrichtigung verarbeiten
Private Sub f2_Minimized()
    HideSubWindows
End Sub
 
Private Sub f3_Minimized()
   HideSubWindows
End Sub
 
Private Sub Form_Resize()
   If Me.WindowState = vbMinimized Then
      HideSubWindows False
   Else
      ShowSubWindows
   End If
End Sub
 
'Form2
Public Event Minimized()
 
Private Sub Form_Resize()
    If Me.WindowState = vbMinimized Then
       RaiseEvent Minimized
    End If
End Sub