Private Declare Function GetTickCount Lib "kernel32" () As Long

Public Sub GenerateZahlen(Arrs() As ArrayWrapper, Dateiname As String)
    Dim FileNr As Long
    FileNr = FreeFile
    Open Dateiname For Output As FileNr ' Datei öffnen
    Dim i As Long, j As Long
    Dim AktAnzahlZahlen As Long
    Dim Indizes() As Long, Zahl() As Long
    ReDim Indizes(UBound(Arrs))
    ReDim Zahl(UBound(Arrs))
    Dim ZahlKommtBereitsVorIndex As Long
    Dim LetzterAufruf As Long
    Do While Indizes(0) <= UBound(Arrs(0).Arr)
        Dim AktTickCount As Long
        AktTickCount = GetTickCount()
        If LetzterAufruf + 100 <= AktTickCount Or LetzterAufruf > _
          AktTickCount Then  '100 ms abstand
            LetzterAufruf = AktTickCount
            ProgressBar1.Value = 100 * (Indizes(0) + 1) / (UBound(Arrs(0).Arr) _
              + 1)
            DoEvents
        End If
 
        ZahlKommtBereitsVorIndex = -1
        For i = 0 To UBound(Arrs)
            Zahl(i) = Arrs(i).Arr(Indizes(i))
            For j = 0 To i - 1
                If Zahl(j) = Zahl(i) Then
                    ZahlKommtBereitsVorIndex = i
                    Exit For
                End If
            Next
        Next
 
        If ZahlKommtBereitsVorIndex < 0 Then
            ' Zahl in Datei schreiben
            WriteLine FileNr, Zahl
            AktAnzahlZahlen = AktAnzahlZahlen + 1
            ZahlKommtBereitsVorIndex = UBound(Arrs)
        End If
 
        'Weiterschalten
        Indizes(ZahlKommtBereitsVorIndex) = Indizes(ZahlKommtBereitsVorIndex) + _
          1
        For i = ZahlKommtBereitsVorIndex To 1 Step -1
            If Indizes(i) > UBound(Arrs(i).Arr) Then
                Indizes(i) = 0
                Indizes(i - 1) = Indizes(i - 1) + 1
            End If
        Next
    Loop
    Close FileNr 'Datei schließen
End Sub