Public Sub LoadResStrings(Frm As Form)
 
  On Error Resume Next
 
  Dim ctl As Control
  Dim obj As Object
  Dim sCtlType As String
  Dim nVal As Integer
 
  'Definition of Form Title
  Frm.Caption = getResString(CInt(Frm.Tag))
 
  'Definition of control element labels
  For Each ctl In Frm.Controls
    sCtlType = TypeName(ctl)
 
    Select Case sCtlType
 
      Case "Label"
        ctl.Caption = getResString(CInt(ctl.Tag))
 
      Case "Menu"
        If Len(ctl.Tag) > 0 Then
          ctl.Caption = getResString(CInt(ctl.Tag))
        Else
          ctl.Tag = ctl.Caption
          ctl.Caption = getResString(CInt(ctl.Caption))
        End If
 
      Case "TabStrip"
        For Each obj In ctl.Tabs
          obj.Caption = getResString(CInt(obj.Tag))
          obj.ToolTipText = getResString(CInt(obj.ToolTipText))
        Next
 
      Case "Toolbar"
        For Each obj In ctl.Buttons
          obj.ToolTipText = getResString(CInt(obj.ToolTipText))
        Next
 
      Case "ListView"
        For Each obj In ctl.ColumnHeaders
          obj.Text = getResString(CInt(obj.Tag))
        Next
 
      Case "ComboBox"
        Dim cmb As ComboBox
        Set cmb = ctl
        Dim cmbIdx As Integer
        With cmb
          For cmbIdx = 0 To .ListCount - 1
            If .ItemData(cmbIdx) <> vbNullString Then
              .list(cmbIdx) = getResString(CInt(.ItemData(cmbIdx)))
            End If
          Next cmbIdx
        End With
 
      Case Else
        nVal = 0
        nVal = val(ctl.Tag)
        If nVal > 0 Then ctl.Caption = getResString(nVal)
        nVal = 0
        nVal = val(ctl.ToolTipText)
        If nVal > 0 Then ctl.ToolTipText = getResString(nVal)
        Err.Clear
 
    End Select
 
  Next
 
  Err.Clear
 
End Sub
 
'Berücksichtigt den Offset der gesetzten Sprache, globale Variable
Public Function getResString(ByVal vId As Integer) As String
  getResString = LoadResString(vId + gl_obsLng)
End Function

Gruß
Dirk

--
?Get it right the first time