Option Explicit
 
Private m_MSelect As CMultiSelect
 
Private Sub Form_Load()
 
  Set m_MSelect = New CMultiSelect
  m_MSelect.Init Me, Label(0), Label(1)
 
End Sub

Option Explicit
 
Private Const gc_GridSpace As Long = 40
 
Private WithEvents m_Form As Form
Private m_Controls As Collection
 
Private m_Enabled As Boolean
'Save start coordinates of selection rectangle
Private m_StartX As Single
Private m_StartY As Single
'Save last position to whipe out old previous rectangle
 
Private m_OldX As Single
Private m_OldY As Single
 
Private m_NowX As Single
Private m_NowY As Single
 
Private m_Visible As Boolean
Private m_Area As Long
 
'-- oder evtl Collection mit Controls übergeben
Public Function Init(ByRef rForm As Form, ParamArray parControls())
 
  Dim c
 
  m_Enabled = False
  m_Visible = False
 
  Set m_Form = rForm
 
  Set m_Controls = New Collection
 
  For Each c In parControls
 
    If TypeOf c Is Control Then
      m_Controls.Add c
    End If
 
  Next c
 
End Function
 
Private Sub m_Form_MouseDown(Button As Integer, Shift As Integer, X As Single, _
  Y As Single)
'
  m_StartX = X
  m_StartY = Y
  m_OldX = X
  m_OldY = Y
  m_Enabled = True
  UnselectControls
 
End Sub
 
Private Sub m_Form_MouseMove(Button As Integer, Shift As Integer, X As Single, _
  Y As Single)
'
  If m_Enabled Then
 
    m_NowX = X
    m_NowY = Y
 
    If (Abs(m_OldX - X) > gc_GridSpace) Or _
       (Abs(m_OldY - Y) > gc_GridSpace) Then
 
      m_Visible = True
      m_OldX = X
      m_OldY = Y
      m_Form.Refresh
 
    End If
  Else
    m_Visible = False
  End If
 
End Sub
 
Private Sub m_Form_MouseUp(Button As Integer, Shift As Integer, X As Single, Y _
  As Single)
'
  If m_Visible Then
    m_Visible = False
    SelectControls
    m_Form.Refresh
  End If
  m_Enabled = False
 
End Sub
 
Private Sub m_Form_Paint()
  If m_Enabled Then
    Draw
  End If
End Sub
 
Private Sub Draw()
 
  Dim dStyle As Long
 
  If m_Visible Then
    dStyle = m_Form.DrawStyle
    m_Form.DrawStyle = vbDash
    m_Form.Line (m_StartX, m_StartY)-(m_NowX, m_NowY), vbRed, B
    m_Form.DrawStyle = dStyle
  End If
 
End Sub
 
Private Sub SelectControls()
 
  Dim c As Control
 
  On Error Resume Next
 
  For Each c In m_Controls
 
    Select Case True
 
      Case TypeOf c Is Label
        Dim l As Label
 
        Set l = c
        If m_StartX < l.Left Then
          If m_NowX > l.Left + l.Width Then
            If m_StartY < l.Top Then
              If m_NowY > l.Top + l.Height Then
                l.BackColor = vbRed
              End If
            End If
 
          End If
        End If
 
      Case Else
 
    End Select
 
 
  Next c
 
End Sub
 
Private Sub UnselectControls()
 
  Dim c As Control
 
  On Error Resume Next
 
  For Each c In m_Controls
    c.BackColor = vbGrayed  'nur Beispiel
  Next c
 
 
End Sub

Gruß
Dirk

--
?Get it right the first time