Option Explicit
Private Type KoordinatenTyp
X As Double
Y As Double
End Type
Private Type KreisBogenTyp
Mittelpunkt As KoordinatenTyp
Startpunkt As KoordinatenTyp
Endpunkt As KoordinatenTyp
End Type
 
Private Function Vektorwinkeld(X1 As Double, Y1 As Double) As Double
Dim Winkel1 As Double
'1. Quadrant
If X1 >= 0 And Y1 >= 0 Then
  If X1 = 0 Then Winkel1 = Atn(1) * 2
  If X1 <> 0 Then Winkel1 = Atn(Y1 / X1)
End If
'2./3. Quadrant
If X1 < 0 Then Winkel1 = Atn(1) * 4 + Atn(Y1 / X1)
'4. Quadrant
If X1 >= 0 And Y1 < 0 Then
  If X1 = 0 Then Winkel1 = Atn(1) * 6
  If X1 <> 0 Then Winkel1 = Atn(1) * 8 + Atn(Y1 / X1)
End If
Vektorwinkeld = Winkel1
End Function
 
Private Function ImUhrzeigersinn(KreisbogenStruktur As KreisBogenTyp) As Boolean
Dim WinkelStartpunkt As Double
Dim WinkelEndpunkt As Double
WinkelStartpunkt = Vektorwinkeld(KreisbogenStruktur.Startpunkt.X - _
  KreisbogenStruktur.Mittelpunkt.X, KreisbogenStruktur.Startpunkt.Y - _
  KreisbogenStruktur.Mittelpunkt.Y)
WinkelEndpunkt = Vektorwinkeld(KreisbogenStruktur.Endpunkt.X - _
KreisbogenStruktur.Mittelpunkt.X, KreisbogenStruktur.Endpunkt.Y - _
KreisbogenStruktur.Mittelpunkt.Y)
Dim Winkelunterschied As Double
Winkelunterschied = WinkelEndpunkt - WinkelStartpunkt
If Winkelunterschied >= 4 * Atn(1) Then Winkelunterschied = _
  Winkelunterschied - 8 * Atn(1)
ImUhrzeigersinn = Winkelunterschied < 0
End Function
 
Private Sub Form_Load()
'Beispiel
Dim Kreisbogen As KreisBogenTyp
Kreisbogen.Mittelpunkt.X = 3
Kreisbogen.Mittelpunkt.Y = 3
Kreisbogen.Startpunkt.X = 3
Kreisbogen.Startpunkt.Y = 4
Kreisbogen.Endpunkt.X = 2
Kreisbogen.Endpunkt.Y = 3
MsgBox ImUhrzeigersinn(Kreisbogen)
End Sub