Option Explicit
 
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds&)
 
Private Pi!, flgBusy As Boolean, flgEnd As Boolean
 
Private Sub Form_Load()
  Pi = Atn(1) * 4
End Sub
 
Private Sub Form_Activate()
 
  Dim i&, SW!, SH!, Offs!, N&, WnkLst!()
 
  DoEvents
  N = 500
  ReDim WnkLst(N - 1)
  With Picture1
    .ScaleMode = vbPixels
    .BackColor = RGB(0, 128, 0)
    SW = .ScaleWidth
    SH = .ScaleHeight
    .AutoRedraw = True
    .ForeColor = RGB(200, 200, 200)
    .DrawStyle = vbDot
    For i = 0 To 9
      Picture1.Line (0, i * SH / 10)-Step(SW, 0)
      Picture1.Line (i * SW / 10, 0)-Step(0, SH)
    Next i
    .DrawStyle = vbSolid
    Set .Picture = .Image
    For i = 0 To N - 1
      WnkLst(i) = SH * 0.4 * Sin(2 * Pi / N * i)
    Next i
    flgBusy = True
    flgEnd = False
    Do
      .Cls
      .CurrentX = SW / 2 + WnkLst(0)
      .CurrentY = SH / 2 + WnkLst((3 * N / 4 + Offs) Mod N)
      For i = 1 To N
        Picture1.Line -(SW / 2 + WnkLst(i Mod N), SH / 2 + WnkLst((3 * (i + N / _
          4) + Offs) Mod N)), RGB(222, 255, 222)
      Next i
      Offs = (Offs + 1) Mod N
      DoEvents
      Call Sleep(10)
    Loop While flgBusy = True
  End With
  flgEnd = True
  Unload Me
 
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
  If flgEnd = False Then
    flgBusy = False
    Cancel = -1
  End If
End Sub

Gruss,

Zardoz