Option Explicit                         'Erzwingt Variablendeklaration
 
'--- Variablen- und Konstantendeklaration
Const ForReading = 1                    'E/A-Modus, Datei zum Lesen öffnen
Const PCFILEPATH = "computer.txt"       'Pfad zur Computerliste
Dim FSO                                 'Dateisystemobjekt
Dim PCFile                              'Dateiobjekt
 
' Objektverweis einer Variable zuweisen
Set FSO = CreateObject("Scripting.FileSystemObject")
 
' Überprüfen, ob die Datei vorhanden ist
If FSO.FileExists(PCFILEPATH) Then
 
  ' Datei zum Lesen öffnen
  Set PCFile = FSO.OpenTextFile(PCFILEPATH, ForReading)
 
  ' Datei bis zum Ende durchlaufen  
  Do Until PCFile.AtEndOfStream
 
    ' Liest die Zeile, übergibt die zeichenfolge an die Funktion 'Ping( _
      Computer)' und gibt das Ergebnis aus
    WScript.echo Ping(PCFile.ReadLine)
 
  Loop
 
  'Datei schliessen
  PCFile.Close
 
Else
  WScript.Echo "FEHLER: '" & PCFILEPATh & "' wurde nicht gefunden!"
End If
 
Function Ping(ByVal Computer)
  Dim WshShell                          'WshShellObjekt
  Dim ExecObject                        'externes Program
  Dim StreamOut                         'Ausgabestrom
  Dim returnValue                       'Rückgabewert
 
  Set WshShell = CreateObject("WScript.Shell")
 
  ' Befehl Ping mit Zugriff auf Datenstrom ausführen
  Set ExecObject = WshShell.Exec("ping -n 1 -w 100 " & Computer)
 
  ' Alle Zeichen aus dem Datenstrom lesen
  StreamOut = ExecObject.StdOut.ReadAll()
 
  ' Ausgabestrom auswerten
  If Instr(LCase(StreamOut), "antwort") > 0 Then
    returnValue =  "'" & Computer & "' ist erreichbar!"
  Else
    returnValue =  "'" & Computer & "' ist NICHT erreichbar!"
  End If
 
  ' Funktionsrückgabewert
  Ping = returnValue
End Function