Option Infer On
Public Class frmSummationDemo
 
    'Zwei Tabellen
    Dim ds As New DataSet
 
    Dim dtparent As New DataTable("Parent")
 
    Dim WithEvents dtchild As New DataTable("Child")
 
 
    Dim dgvParent As New DataGridView With _
        {.Parent = Me, .Width = 200}
 
    Dim dgvChild As New DataGridView With _
        {.Parent = Me, .Width = 200, .Left = 210}
 
 
 
    Private Sub frmSummationDemo_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
 
        'Einige Testdaten in ChildTable
        With dtchild
            .Columns.Add("SatzID", GetType(Integer))
            .Columns.Add("Art", GetType(Integer))
            .Columns.Add("Menge", GetType(Double))
            .Columns("Menge").DefaultValue = 0
 
            .Rows.Add(1, 1, 22) : .Rows.Add(2, 1, 33) : .Rows.Add(3, 1, 66)
            .Rows.Add(1, 1, 2.5) : .Rows.Add(2, 1, 3.5) : .Rows.Add(3, 1, 6.5)
            .Rows.Add(1, 2, 12.7) : .Rows.Add(2, 2, 13.5) : .Rows.Add(3, 2, _
              16.2)
            .Rows.Add(1, 2, 2.7) : .Rows.Add(2, 2, 3.9) : .Rows.Add(3, 2, 19.5)
        End With
 
        'Spalten und Schlüssel in der ParentTable erstellen
        With dtparent
            .Columns.Add("SatzID", GetType(Integer))
            .Columns.Add("Art", GetType(Integer))
            .PrimaryKey = _
                New DataColumn() {.Columns("SatzID"), .Columns("Art")}
        End With
 
        'Füllen der ParentTable entsprechend den Child-Werten 
        '(LINQ: anonyme Typen - Distinct: eindeutiger Schlüssel)
        Dim s = From x As DataRow In dtchild.Rows.OfType(Of DataRow)() _
                Select id = x("SatzID"), art = x("Art") Distinct
 
        For Each el In s
            dtparent.Rows.Add(el.id, el.art)
        Next el
 
        'Tabellen und Relation in einem Dataset
        With ds
            .Tables.Add(dtparent) : .Tables.Add(dtchild)
 
            'Datarelation über zwei Spalten
            .Relations.Add(New DataRelation("SatzID_Art", _
                                            {dtparent.Columns("SatzID"), _
                                             dtparent.Columns("Art")}, _
                                            {dtchild.Columns("SatzID"), _
                                             dtchild.Columns("Art")}))
        End With
 
        'Expressionspalte / gegliedert nach "SatzID" und "Art"
        dtparent.Columns.Add("SummeExpr", GetType(Double), "Sum(Child.Menge)")
 
        dgvChild.DataSource = dtchild
        dgvParent.DataSource = dtparent
 
    End Sub
End Class