Public Class Form1
    Dim dt As New DataTable
    Dim bs As New BindingSource
    Dim MoveRowQuellIndex As Integer
    Private Sub Form1_Load(ByVal sender As System.Object, _
       ByVal e As System.EventArgs) Handles MyBase.Load
 
        bs.DataSource = dt
        DataGridView1.DataSource = bs
        dt.Columns.Add("Nummern", GetType(UInteger))
        dt.Columns.Add("Content", GetType(String))
 
        For i As Integer = 0 To 99
            Dim row As DataRow = dt.NewRow
            row.Item(0) = i + 1 
            row.Item(1) = "Content in Zeile " & CStr(i + 1)
            dt.Rows.Add(row)
        Next i
 
        For i As Integer = 0 To DataGridView1.Columns.Count - 1
            DataGridView1.Columns(i).SortMode = _
            DataGridViewColumnSortMode.NotSortable
        Next i
        MoveRowQuellIndex = -1
    End Sub
 
    Private Sub RowHeaderMouseDoubleClick(ByVal sender As Object, _
             ByVal e As System.Windows.Forms.DataGridViewCellMouseEventArgs) _
             Handles DataGridView1.RowHeaderMouseDoubleClick
 
        If e.Button = Windows.Forms.MouseButtons.Right Then
            If e.RowIndex >= 0 Then
                If MoveRowQuellIndex >= 0 Then
                    'Verschiebung durchführen
                    MoveTableRow(MoveRowQuellIndex, e.RowIndex)
                    ResetRowMove()
                Else
                    'Quelle der Verschiebung notieren
                    MoveRowQuellIndex = e.RowIndex
                    DataGridView1.Cursor = Cursors.Cross
                    DataGridView1.TopLeftHeaderCell.Value = _
                    " [" & CStr(MoveRowQuellIndex) & "]"
                End If
            Else
                ResetRowMove()
            End If
        End If
 
    End Sub
 
    Private Function MoveTableRow(ByVal quellindex As Integer, _
        ByVal zielindex As Integer) As Boolean
        If quellindex < 0 Or quellindex >= dt.Rows.Count Then Return False
        If zielindex < 0 Or zielindex >= dt.Rows.Count Then Return False
        If quellindex = zielindex Then Return True
 
        Dim row As DataRow = dt.NewRow
        For i As Integer = 0 To dt.Columns.Count - 1
            row.Item(i) = dt.Rows(quellindex).Item(i)
        Next i
        dt.Rows.RemoveAt(quellindex)
        dt.Rows.InsertAt(row, zielindex)
        For i As Integer = 0 To dt.Rows.Count - 1
            dt.Rows(i).Item("Nummern") = i + 1
        Next i
        Return True
    End Function
 
    Private Sub ResetRowMove()
        MoveRowQuellIndex = -1
        DataGridView1.Cursor = Cursors.Default
        DataGridView1.TopLeftHeaderCell.Value = ""
    End Sub
 
End Class