Public Class frmCombos
    'Gemeinsame Liste
    Dim lst As New List(Of String)({"A", "B", "C", "D", "E"})
    'Liste der Comboboxen 
    Dim cbs As New List(Of ComboBox)
 
 
    Private Sub frmCombos_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
 
        CreateCombos()
    End Sub
 
    Private Sub CreateCombos()
 
        For i As Integer = 0 To lst.Count - 1
            Dim bs As New BindingSource With {.DataSource = lst}
            cbs.Add(New ComboBox With _
                {.Parent = Me, .DataSource = bs, _
                 .Top = i * 40, .Name = i.ToString, _
                 .DropDownStyle = ComboBoxStyle.DropDown, _
                 .SelectedIndex = i, .Tag = i})
 
            'Zuordnung der Eventhandler-Routine
            AddHandler cbs(i).SelectedIndexChanged, _
                    AddressOf SelectedIndexChanged
        Next i
    End Sub
 
 
    Private Sub SelectedIndexChanged(sender As Object, _
             e As System.EventArgs)
 
        Dim cbo As ComboBox = DirectCast(sender, ComboBox)
 
        'Der Listen-Index der Box, deren Selectedindex 
        'vom Benutzer geändert worden ist
        Dim comboindex As Integer = CInt(cbo.Name)
 
        'In der Tag-Eigenschaft steht noch der bisherige 
        'Selectedindex
        Dim oldindex As Integer = CInt(cbo.Tag)
 
        For i As Integer = 0 To cbs.Count - 1
           If Not i = comboindex AndAlso _
              cbo.SelectedIndex = cbs(i).SelectedIndex Then
 
              'Wechsel des SelectedIndex der Box,
              'die den neu eingestellten Wert bisher angezeigt hat
              cbs(i).SelectedIndex = oldindex
              cbs(i).Tag = oldindex
            End If
        Next i
        cbo.Tag = cbo.SelectedIndex
    End Sub
 
End Class