Public Class frmRebind
 
    'steht sonst im Designer-Code
    Dim WithEvents cmdSuchStarten As New Button _
        With {.Parent = Me, .Text = "Suchen"}
 
    Dim WithEvents txtKdnr As New TextBox With _
        {.Parent = Me, .Top = 50}
    Dim WithEvents txtName As New TextBox With _
        {.Parent = Me, .Top = 80}
    Dim WithEvents txtOrt As New TextBox With _
        {.Parent = Me, .Top = 110}
 
    Dim bs As New BindingSource
    Dim dt As DataTable
 
 
    Private Sub cmdSuchStarten_Click(sender As Object, _
               e As EventArgs) Handles cmdSuchStarten.Click
 
        Static kdnr As Integer = 0
 
        'Tabellen-Bindung unterbrechen
        bs.SuspendBinding()
 
        'Neue Tabelle erstellen 
        'Hier stünde die Access-Abfrage eines Datensatzes
        Dim dt As New DataTable
 
        'Demodaten
        With dt.Columns
            .Add("kdnr") : .Add("name") : .Add("ort")
        End With
        kdnr += 1
        If kdnr Mod 2 = 0 Then
            dt.Rows.Add({kdnr.ToString, "Hans Müller", "Hamburg"})
        Else
            dt.Rows.Add({kdnr.ToString, "Georg Schneider", "München"})
        End If
 
 
        'TabellenBindung herstellen
        bs.DataSource = dt
 
        'Bindung der Controls (nur beim ersten Mal)
        SetBindings()
 
        'Bindung wieder aufnehmen
        bs.ResumeBinding()
 
        bs.Position = 0
    End Sub
 
    Private Sub SetBindings()
        'Bindung der Bindingsource an die Controls
        'nach dem ersten Füllen der Tabelle
 
        If txtKdnr.DataBindings.Count = 1 Then 
           Exit Sub 'bereits eingerichtet
        End If
 
        txtKdnr.DataBindings.Add("Text", bs, "kdnr")
        txtName.DataBindings.Add("Text", bs, "name")
        txtOrt.DataBindings.Add("Text", bs, "ort")
    End Sub
End Class