Private Function findrow(ByVal dt As DataTable, _
        ByVal M1 As String, ByVal M2 As String) As Integer
 
        'Suche nach dem Index der Begegnung 
        For i As Integer = 0 To dt.Rows.Count - 1
            If (dt.Rows(i)("TeamA").ToString = M1 And _
                dt.Rows(i)("TeamB").ToString = M2) _
                Or _
                (dt.Rows(i)("TeamA").ToString = M2 And _
                 dt.Rows(i)("TeamB").ToString = M1) Then
                Return i
            End If
        Next i
        Return -1 'Begegnung in dt nicht gefunden
    End Function
 
 
 
    Public Sub Spielstatistik()
 
        'Statistiktabelle: Spalten erstellen
        Dim dtStatistik As New DataTable
        With dtStatistik.Columns
            .Add("TeamA") : .Add("TeamB") 
            .Add("Begegnungen", GetType(UShort))
            .Add("kein Tor", GetType(UShort))
            .Add("1 Tor", GetType(UShort))
            .Add("2 Tore", GetType(UShort))
            .Add("3 Tore oder mehr", GetType(UShort))
        End With
 
        'Schleife über alle Tabellenzeilen (geladene Excel-Tabelle)
        For i As Integer = 0 To oDs.Tables(0).Rows.Count - 1
            Dim row As DataRow = oDs.Tables(0).Rows(i)
 
            'alle Einträge ab gewähltem Datum bearbeiten
            If dtpDatum.Value <= CDate(row("Datum")) Then
 
                'aktuelle Begegnung in der Statistiktabelle suchen
                Dim rowindex As Integer = _
                    findrow(dtStatistik, row("TeamA").ToString.ToUpper, _
                            row("TeamB").ToString.ToUpper)
 
                'Fall Index nicht gefunden (-1): 
                'neuer Statistik-Eintrag wird erstellt
                If rowindex = -1 Then
                    dtStatistik.Rows.Add(dtStatistik.NewRow)
                    rowindex = dtStatistik.Rows.Count - 1
 
                    'neuen Statistikeintrag initialisieren
                    With dtStatistik.Rows(rowindex)
                        .Item("TeamA") = row("TeamA").ToString.ToUpper
                        .Item("TeamB") = row("TeamB").ToString.ToUpper
                        For k As Integer = 2 To 6
                            .Item(k) = 0
                        Next k
                    End With
                End If
 
 
                'Statistiken zur Begegnung i erstellen
                With dtStatistik.Rows(rowindex)
                    .Item("Begegnungen") = _
                    CUShort(.Item("Begegnungen")) + 1US
 
                    'Anzahl der insgesamt geschossenen Tore im Spiel
                    Dim tore As UShort = _
                    CUShort(row("ToreTeamA")) + CUShort(row("ToreTeamB"))
 
                    If tore >= 3 Then
                        .Item(6) = CUShort(.Item(6)) + 1
                    ElseIf tore = 2 Then
                        .Item(5) = CUShort(.Item(5)) + 1
                    ElseIf tore = 1 Then
                        .Item(4) = CUShort(.Item(4)) + 1
                    Else
                        .Item(3) = CUShort(.Item(3)) + 1
                    End If
                End With
            End If
        Next i
 
        'Statistiktabelle an Bindingsource binden
        'für Anzeige im GridView
        bs.DataSource = dtStatistik
 
    End Sub