Public Class frmTextBinding
 
    ''' <summary>Aufbewahrung eines Textes</summary>
    Private Class TextLine
        Private _text As String
 
        Public Sub New(ByVal text As String)
            _text = text
        End Sub
 
        Public Property Text() As String
            Set(value As String)
                _text = value
            End Set
            Get
                Return _text
            End Get
        End Property
    End Class
 
    Dim bl As New System.ComponentModel.BindingList(Of TextLine)
 
    Dim bs As New BindingSource
 
    Dim tbo As New TextBox With {.Parent = Me}
    Dim lbo As New ListBox With {.Parent = Me, .Top = 40}
 
    Private Sub frmTextBinding_Load(sender As System.Object, _
                       e As System.EventArgs) Handles MyBase.Load
 
        'Texte zeilenweise lesen
        Dim texte() As String = _
           IO.File.ReadAllLines("C:\daten\demodaten.txt")
 
        'Liste mit Klasseninstanzen füllen
        For Each t As String In texte
            bl.Add(New TextLine(t))
        Next t
 
        bl.AllowEdit = True
 
        'Bindingsource zwischen Texte und Controls
        bs.DataSource = bl
 
        'Datenbindung herstellen
        tbo.DataBindings.Add("Text", bs, "Text", True, _
            DataSourceUpdateMode.OnPropertyChanged)
 
        lbo.DisplayMember = "Text"
        lbo.DataSource = bs
    End Sub
End Class