Public Class frmKombiChart
 
    Dim cht As New System.Windows.Forms.DataVisualization.Charting.Chart _
        With {.Parent = Me, .Dock = DockStyle.Fill}
 
    Private Sub frmKombiChart_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
 
        'Tabelle mit zwei Spalten
        Dim dtb As New DataTable
        dtb.Columns.Add("Date", GetType(Date))
        dtb.Columns.Add("KWH", GetType(Double))
 
        With dtb.Rows
            .Add(CDate("1.1.2013"), 23.4)
            .Add(CDate("2.1.2013"), 24.4)
            .Add(CDate("3.1.2013"), 28.4)
            .Add(CDate("6.1.2013"), 27.4)
        End With
 
        'Maximalwerte (bezogen auf das Datum in der Table)
        Dim max() As Double = {33.4, 34.9, 34.4, 30.4}
 
        'Gebundene Datenserie (Column)
        cht.ChartAreas.Add("Area")
        cht.Series.Add("Produced")
        With cht.Series("Produced")
            .ChartType = DataVisualization.Charting.SeriesChartType.Column
            .Points.DataBind(dtb.AsEnumerable, "Date", "KWH", "")
            .ChartArea = "Area"
        End With
 
        'explizit erstellte Datenserie (Line)
        cht.Series.Add("Maximum")
        With cht.Series("Maximum")
            .ChartType = DataVisualization.Charting.SeriesChartType.Line
            For i As Integer = 0 To dtb.Rows.Count - 1
                .Points.AddXY(dtb.Rows(i)("Date"), max(i))
            Next i
            .Color = Color.Red
            .ChartArea = "Area"
        End With
    End Sub
End Class