Private Const VT_BYREF% = 16384         '
Private Type SAFEARRAYBOUND
 cElements As Long
 lLbound As Long
End Type
Private Declare Sub GetMemLong Lib "msvbvm60" Alias "GetMem4" ( _
                ByVal Addr As Long, retval As Long)
Private Declare Sub GetMemInt Lib "msvbvm60" Alias "GetMem2" ( _
                ByVal Addr As Long, retval As Integer)
Private Declare Function SafeArrayRedim Lib "oleaut32.dll" ( _
                ByRef pSa As Long, _
                ByRef psaBoundNew As SAFEARRAYBOUND) _
                As Long
 
Public Function EmptyArray( _
                ByRef varArray As Variant, _
                Optional loBound& = 0) _
                As Boolean
 If Not IsArray(varArray) Then Exit Function
 Dim pVariant As Long
 Dim vType As Integer
 Dim pSa As Long
 Dim pFarSa As Long
 ReDim varArray(0)
 pVariant = VarPtr(varArray)
 GetMemInt pVariant, vType
 If vType And VT_BYREF Then
  GetMemLong pVariant + 8, pFarSa
  GetMemLong pFarSa, pSa
 Else
  GetMemLong pVariant + 8, pSa
 End If
 If pSa = 0 Then
  Erase varArray
  EmptyArray = False
  Exit Function
 End If
 Dim saBound As SAFEARRAYBOUND
 saBound.lLbound = loBound
 Dim ret&
 ret = SafeArrayRedim(ByVal pSa, saBound)
 EmptyArray = (ret = 0)
End Function