Public Class frmFilterDemo
 
    Dim WithEvents tbo As New TextBox With {.Parent = Me, .Top = 5}
    Dim WithEvents lbo As New ListBox With {.Parent = Me, .Top = 50}
 
    Dim dt As New DataTable
    Dim bs As New BindingSource
 
    Private Sub frmFilterDemo_Load(sender As System.Object, e As _
      System.EventArgs) _
        Handles MyBase.Load
 
        CreateRandomListContent(500)
 
        bs.DataSource = dt
        bs.Sort = "Values ASC"
 
        lbo.DisplayMember = "Values"
        lbo.DataSource = bs
    End Sub
 
    Public Sub CreateRandomListContent(ByVal number As Integer)
 
        'Zufällige Einträge für die Listbox erzeugen
        Dim rndm As New Random, c As Char, stb As New System.Text.StringBuilder
        dt.Columns.Clear()
        dt.Columns.Add("Values")
        For i As Integer = 0 To number - 1
            Dim l As Integer = rndm.Next(3, 10)
            stb.Clear()
            For k As Integer = 0 To l - 1
                stb.Append(Chr(rndm.Next(65, 90)))
            Next k
            dt.Rows.Add(stb.ToString)
        Next i
    End Sub
 
    Private Sub tbo_TextChanged(sender As Object, e As System.EventArgs) _
        Handles tbo.TextChanged
        If String.IsNullOrWhiteSpace(tbo.Text) Then
            bs.Filter = Nothing
        Else
            'Textbox-Inhalt zum Filtern der Liste verwenden
            bs.Filter = "Values LIKE '" & tbo.Text.ToUpper.Trim & "*'"
        End If
    End Sub
 
    Private Sub lbo_SelectedValueChanged(sender As Object, e As _
      System.EventArgs) _
        Handles lbo.SelectedValueChanged
        If lbo.SelectedValue Is Nothing Then
            Me.Text = "keine Auswahl"
        Else
            'den jeweils ausgewählten Listen-Eintrag in den Form-Text eintragen 
            Me.Text = CType(lbo.SelectedValue, DataRowView).Row( _
              "Values").ToString
        End If
    End Sub
End Class