Public Function CreatePie _
      (ByVal size As System.Drawing.Size, _
       ByVal frequencies As List(Of Double)) As Bitmap
 
    Dim s As Double = Aggregate el As Double In frequencies Into Sum()
 
    Dim bmp As New Bitmap(size.Width, size.Height)
 
    Using g As Graphics = Graphics.FromImage(bmp),
        green As New SolidBrush(Color.Green), _
        red As New SolidBrush(Color.Red), _
        yellow As New SolidBrush(Color.Yellow)
 
        Dim rec As New Rectangle(0, 0, size.Width, size.Height)
        Dim start As Single = 0, angle As Single
 
        For i As Integer = 0 To frequencies.Count - 1
           angle = CSng(frequencies(i) / s * 360)
           Select Case i Mod 3
              Case 0
                 g.FillPie(red, rec, start, angle)
              Case 1
                 g.FillPie(green, rec, start, angle)
              Case 2
                 g.FillPie(yellow, rec, start, angle)
            End Select
            start += angle
        Next i
    End Using
 
    Return bmp
End Function

Dim frequencies As New List(Of Double)({100, 200, 300, 400, 500})
 
With PictureBox1
   .Image = CreatePie(.Size, frequencies)
End With