Imports System.Windows.Forms
Imports System.Drawing
Imports System
 
Public Class frmFilesDisplay
 
    'Klasse für Angaben zu einem File
    Private Class FileInfos
        Public Property appicon As System.Drawing.Icon
        Public Property filename As String
        Public Property Extension As String
        Public Property LastWriteTime As Date
 
        Public Sub New(ByVal file As String)
            filename = file
            Extension = IO.Path.GetExtension(file)
            appicon = Icon.ExtractAssociatedIcon(file)
            LastWriteTime = New IO.FileInfo(file).LastWriteTime
        End Sub
    End Class
 
    'Liste mit Angaben zu Files
    Dim filelist As New System.Collections.Generic.List(Of FileInfos)
 
    Dim WithEvents dgv As New DataGridView With _
        {.Parent = Me, .Dock = System.Windows.Forms.DockStyle.Fill, _
         .AllowUserToAddRows = False, .AllowUserToDeleteRows = False, _
         .ReadOnly = True}
 
    Private Sub frmFilesDisplay_Load(ByVal sender As System.Object, _
                            ByVal e As System.EventArgs) Handles MyBase.Load
 
        'Liste mit Angaben zu Files füllen
        Dim direc As String = _
          My.Computer.FileSystem.SpecialDirectories.MyDocuments
        For Each file As String In My.Computer.FileSystem.GetFiles _
            (direc, _
            Microsoft.VisualBasic.FileIO.SearchOption.SearchTopLevelOnly, "*.*")
            filelist.Add(New FileInfos(file))
        Next
        dgv.DataSource = filelist
    End Sub
 
    Private Sub dgv_CellClick(ByVal sender As Object, _
            ByVal e As DataGridViewCellEventArgs) Handles dgv.CellClick
      If e.columnindex >= 0 then    
        MessageBox.Show _
        ("Sie haben in die Spalte " & dgv.Columns( _
        e.ColumnIndex).DataPropertyName & " geclickt")
      End If   
    End Sub
 
    Private Sub dgv_RowEnter(ByVal sender As Object, _
        ByVal e As DataGridViewCellEventArgs) Handles dgv.RowEnter
        Me.Text = "Aktuelle Zeile " & CStr(e.RowIndex)
    End Sub
End Class