Const ProduktSpalte As String = "Produkt"
Const ProduktPreis As String = "Preis (€)"
Const OrderDatum As String = "Datum"
 
'Deklaration der erforderlichen Objekte
Dim dtb As New DataTable 'Datentabelle
Dim bs As New BindingSource 'Für Bindung
 
Dim WithEvents dgv As New DataGridView _
    With {.Parent = Me, .Top = 0, .Height = 110} 'Für Ansicht/Edits
 
Dim lblGesamtpreis As New Label With {.parent = Me, .top = 120}
 
Private Sub Load(ByVal sender As System.Object, _
     ByVal e As System.EventArgs) Handles MyBase.Load
 
    'Die Spalten der Tabelle
    With dtb.Columns
       .Add(ProduktSpalte, GetType(String))
       .Add(ProduktPreis, GetType(Decimal))
       .Add(OrderDatum, GetType(Date))
    End With
 
    'Einige Datenzeilen mit zufälligem Preis
    Dim rndm As New Random(12345)
    With dtb.Rows
        For i As Integer = 1 To 20
           Dim r As DataRow = dtb.NewRow
           r.Item(ProduktSpalte) = "Produkt " & CStr(i)
           r.Item(ProduktPreis) = Math.Round(CDec(rndm.NextDouble * 10), 2)
           r.Item(OrderDatum) = DateAdd(DateInterval.Hour, -i * 2.5, Now)
           .Add(r)
        Next i
    End With
 
    'Für das Management und die Ansicht der Daten
    bs.DataSource = dtb
    dgv.DataSource = bs
 
    dgv.Columns(ProduktPreis).DefaultCellStyle.Alignment = _
            DataGridViewContentAlignment.MiddleRight
 
    dgv.Columns(ProduktPreis).DefaultCellStyle.Format = "0.00 EUR"
 
    'Berechnung des Gesamtpreises
    Dim Gesamtpreis As Decimal = _
    Aggregate r As DataRow In dtb Into Sum(CDec(r.Item(ProduktPreis)))
    'Anzeige des Gesamtpreises
    lblGesamtpreis.text = CStr(Gesamtpreis)
End Sub