Public Class Form1
    Declare Function LineDDA Lib "gdi32" (X1 As Int32, Y1 As Int32, X2 As _
      Int32, Y2 As Int32, Callback As LDDAProc, lParam As IntPtr) As Int32
    Delegate Sub LDDAProc(x As Int32, y As Int32, lParam As IntPtr)
    Private pos As Int32, plist As New List(Of Point)
    Private WithEvents Pb As New PictureBox With {.Dock = DockStyle.Fill, _
      .BackColor = Color.Black, .Parent = Me}
    Private WithEvents T As New Timer With {.Interval = 10, .Enabled = True}
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles MyBase.Load
        LineDDA(30, 20, 240, 230, AddressOf LineDDAProc, Nothing)
        LineDDA(240, 230, 240, 20, AddressOf LineDDAProc, Nothing)
        LineDDA(240, 20, 30, 230, AddressOf LineDDAProc, Nothing)
        LineDDA(30, 230, 30, 20, AddressOf LineDDAProc, Nothing)
    End Sub
 
    Private Sub LineDDAProc(x As Int32, y As Int32, lParam As IntPtr)
        plist.Add(New Point(x, y))
    End Sub
 
    Private Sub T_Tick(sender As Object, e As System.EventArgs) Handles T.Tick
        pos = If(pos < plist.Count - 2, pos + 2, 0)
        Pb.Invalidate()
    End Sub
 
    Private Sub Pb_Paint(sender As Object, e As _
      System.Windows.Forms.PaintEventArgs) Handles Pb.Paint
        e.Graphics.SmoothingMode = Drawing2D.SmoothingMode.AntiAlias
        e.Graphics.DrawLines(Pens.Silver, plist.ToArray)
        e.Graphics.FillEllipse(Brushes.Yellow, plist(pos).X - 15, plist(pos).Y _
          - 15, 30, 30)
    End Sub
End Class