Public Function OrderByRules _
             (ByVal ListToOrder As System.Collections.Generic.List(Of String), _
              ByVal rules As System.Collections.Generic.List(Of String), _
              Optional ByRef Meldung As String = "") _
              As System.Collections.Generic.List(Of String)
 
        Meldung = ""
        If ListToOrder Is Nothing OrElse ListToOrder.Count < 2 Then
            Meldung = "Ungeeignete Liste" : Return Nothing
        End If
        If rules Is Nothing OrElse rules.Count < 1 Then
            Meldung = "Fehlende Regeln" : Return Nothing
        End If
        If ListToOrder.Contains(Nothing) OrElse rules.Contains(Nothing) Then
            Meldung = "Liste oder Regel-Liste enthält Nullverweis" 
            Return Nothing
        End If
 
        Dim l As Integer = _
        Aggregate listentry As String In ListToOrder Distinct Into Count()
        If l <> ListToOrder.Count Then
            Meldung = "Liste enthält Mehrfacheinträge" : Return Nothing
        End If
        l = Aggregate listentry As String In rules Distinct Into Count()
        If l <> rules.Count Then
            Meldung = "Regel-Liste enthält Mehrfacheinträge" : Return Nothing
        End If
 
        'Listeneinträge aufspalten: 
        'regelbelegte Einträge kommen in rList, freie in fList
        Dim entry As String = "", entrybehind As String = ""
        Dim listindex As Integer
        Dim rList As New List(Of String) 'Liste mit regelbelegten Einträgen
        Dim fList As New List(Of String) 'Liste für freie Einträge
        fList.AddRange(ListToOrder) 'erstmal alles in fList
        For i As Integer = 0 To rules.Count - 1
            If Not GetRule(rules(i), entrybehind, entry) Then
                Meldung = "Unbrauchbarer Listeneintrag" : Return Nothing
            End If
            listindex = fList.IndexOf(entry)
            If listindex >= 0 Then rList.Add(entry) : fList.Remove(entry)
            listindex = fList.IndexOf(entrybehind)
            If listindex >= 0 Then rList.Add(entrybehind) : fList.Remove( _
              entrybehind)
        Next i
 
        If rList.Count > 0 Then
            'Regelwerk auf rList anwenden: 
            'so lange, bis alle Regeln eingehalten sind
            Dim entrymoved As Boolean, _
            zähler As Integer = 0, index_behind As Integer
            Do
                entrymoved = False
                For i As Integer = 0 To rules.Count - 1
                    GetRule(rules(i), entrybehind, entry)
                    index_behind = rList.IndexOf(entrybehind)
                    listindex = rList.IndexOf(entry)
                    If listindex >= 0 And index_behind >= 0 Then
                        If listindex > index_behind Then
                            rList.Remove(entrybehind) : rList.Add(entrybehind)
                            entrymoved = True
                        End If
                    End If
                Next i
                zähler += 1
                If zähler >= rList.Count Then
                    Meldung = "Inkonsistentes Regelwerk" 
                    Return Nothing
                End If
            Loop While entrymoved
        End If
 
        fList.Sort()  'Standard-Stringcomparer beim Sortieren
        rList.AddRange(fList) 'freie Liste anhängen
        If Not CheckRules(rList, rules) Then
            Meldung = "Anordnungsfehler !!!!" : Return Nothing
        End If
        Return rList
    End Function