Public Class Form1
    Private bmp As New Bitmap(Me.Icon.ToBitmap)
    Private gray As Boolean
    Private WithEvents Pb As New PictureBox
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles MyBase.Load
        Pb.SetBounds(130, 130, 32, 32)
        Pb.Image = bmp
        Me.Controls.Add(Pb)
    End Sub
 
    Private Sub Pb_MouseDown(ByVal sender As Object, ByVal e As _
      System.Windows.Forms.MouseEventArgs) Handles Pb.MouseDown
        gray = Not gray
        If gray Then
            Pb.Image = ColorToGray(bmp)
        Else
            Pb.Image = bmp
        End If
    End Sub
 
    Private Function ColorToGray(ByVal bm As Bitmap) As Bitmap
        Dim cm As New Imaging.ColorMatrix(New Single()() _
                      {New Single() {0.3, 0.3, 0.3, 0, 0}, _
                       New Single() {0.59, 0.59, 0.59, 0, 0}, _
                       New Single() {0.11, 0.11, 0.11, 0, 0}, _
                       New Single() {0, 0, 0, 1, 0}, _
                       New Single() {0, 0, 0, 0, 1}})
        Dim nbm As New Bitmap(bm.Width, bm.Height)
        Using iattr As New Imaging.ImageAttributes(), g As Graphics = _
          Graphics.FromImage(nbm)
            Dim rect As New Rectangle(0, 0, nbm.Width, nbm.Height)
            iattr.SetColorMatrix(cm)
            g.DrawImage(bm, rect, 0, 0, bm.Width, bm.Height, _
              GraphicsUnit.Pixel, iattr)
        End Using
        Return nbm
    End Function
End Class