'Ver- und Entschlüsselung:
 
 
    ''' <summary>
    ''' Daten verschlüsseln und in Datei speichern
    ''' </summary>
    ''' <param name="sData">Daten, die verschlüsselt werden sollen</param>
    ''' <param name="sPassword">Passwort zum Verschlüsseln der Daten</param>
    ''' <param name="sFile">Datei, in der die Daten gespeichert werden</param>
    ''' <remarks>Das verwendete Passwort wird auch wieder zum Entschlüsseln 
    ' benötigt</remarks>
    Public Sub EncryptData(ByVal sData As String, ByVal sPassword As String, _
      ByVal sFile As String)
 
        Dim rd As New RijndaelManaged
 
        Dim md5 As New MD5CryptoServiceProvider
        Dim key() As Byte = md5.ComputeHash(Encoding.UTF8.GetBytes(sPassword))
 
        md5.Clear()
        rd.Key = key
        rd.GenerateIV()
 
        Dim iv() As Byte = rd.IV
        Dim ms As New MemoryStream
 
        ms.Write(iv, 0, iv.Length)
 
        Dim cs As New CryptoStream(ms, rd.CreateEncryptor, _
          CryptoStreamMode.Write)
        Dim data() As Byte = System.Text.Encoding.UTF8.GetBytes(sData)
 
        cs.Write(data, 0, data.Length)
        cs.FlushFinalBlock()
 
        Dim encdata() As Byte = ms.ToArray()
 
        My.Computer.FileSystem.WriteAllBytes(sFile, encdata, False)
 
        cs.Close()
        rd.Clear()
    End Sub
 
    ''' <summary>
    ''' Daten aus Datei lesen und entschlüsseln
    ''' </summary>
    ''' <param name="sPassword">Passwort zum Entschlüsseln der Daten</param>
    ''' <param name="sFile">Datei, in der die Daten gespeichert sind</param>
    ''' <returns>Entschlüsselte Daten als String</returns>
    Public Function DecryptData(ByVal sPassword As String, ByVal sFile As _
      String) As String
        Dim rd As New RijndaelManaged
        Dim rijndaelIvLength As Integer = 16
        Dim md5 As New MD5CryptoServiceProvider
        Dim key() As Byte = md5.ComputeHash(Encoding.UTF8.GetBytes(sPassword))
 
        md5.Clear()
 
        Dim encdata() As Byte = My.Computer.FileSystem.ReadAllBytes(sFile)
        Dim ms As New MemoryStream(encdata)
        Dim iv(15) As Byte
 
        ms.Read(iv, 0, rijndaelIvLength)
        rd.IV = iv
        rd.Key = key
 
        Dim cs As New CryptoStream(ms, rd.CreateDecryptor, _
          CryptoStreamMode.Read)
 
        Dim data(ms.Length - rijndaelIvLength) As Byte
        Dim i As Integer = cs.Read(data, 0, data.Length)
 
        Return System.Text.Encoding.UTF8.GetString(data, 0, i)
        cs.Close()
        rd.Clear()
    End Function