Public Class MyList(Of T)
   Implements IList(Of T)
 
   Private m_list As List(Of T)
 
   Public Event ListAdd(ByVal sender As Object, ByVal e As EventArgs)
   Public Event ListClear(ByVal sender As Object, ByVal e As EventArgs)
   Public Event ItemRemoved(ByVal sender As Object, ByVal item As T)
   Public Event ItemChanged(ByVal sender As Object, ByVal item As T)
 
   Public Sub New()
      m_list = New List(Of T)
   End Sub
 
   Public Sub Add(ByVal item As T) Implements _
     System.Collections.Generic.ICollection(Of T).Add
      m_list.Add(item)
      RaiseEvent ListAdd(Me, New EventArgs)
   End Sub
 
   Public Sub Clear() Implements System.Collections.Generic.ICollection(Of _
     T).Clear
      m_list.Clear()
      RaiseEvent ListClear(Me, New EventArgs)
   End Sub
 
   Public Function Contains(ByVal item As T) As Boolean Implements _
     System.Collections.Generic.ICollection(Of T).Contains
      Return m_list.Contains(item)
   End Function
 
   Public Sub CopyTo(ByVal array() As T, ByVal arrayIndex As Integer) _
     Implements System.Collections.Generic.ICollection(Of T).CopyTo
      m_list.CopyTo(array, arrayIndex)
   End Sub
 
   Public ReadOnly Property Count() As Integer Implements _
     System.Collections.Generic.ICollection(Of T).Count
      Get
         Return m_list.Count
      End Get
   End Property
 
   Public ReadOnly Property IsReadOnly() As Boolean Implements _
     System.Collections.Generic.ICollection(Of T).IsReadOnly
      Get
         Return False
      End Get
   End Property
 
   Public Function Remove(ByVal item As T) As Boolean Implements _
     System.Collections.Generic.ICollection(Of T).Remove
      m_list.Remove(item)
      RaiseEvent ItemRemoved(Me, item)
   End Function
 
   Public Function IndexOf(ByVal item As T) As Integer Implements _
     System.Collections.Generic.IList(Of T).IndexOf
      Return m_list.IndexOf(item)
   End Function
 
   Public Sub Insert(ByVal index As Integer, ByVal item As T) Implements _
     System.Collections.Generic.IList(Of T).Insert
      m_list.Insert(index, item)
   End Sub
 
   Default Public Property Item(ByVal index As Integer) As T Implements _
     System.Collections.Generic.IList(Of T).Item
      Get
         Return m_list(index)
      End Get
      Set(ByVal value As T)
         m_list(index) = value
         RaiseEvent ItemChanged(Me, value)
      End Set
   End Property
 
   Public Sub RemoveAt(ByVal index As Integer) Implements _
     System.Collections.Generic.IList(Of T).RemoveAt
      m_list.RemoveAt(index)
   End Sub
 
   Public Function GetEnumerator() As System.Collections.Generic.IEnumerator(Of _
     T) Implements System.Collections.Generic.IEnumerable(Of T).GetEnumerator
      Return m_list.GetEnumerator
   End Function
 
   Public Function GetEnumerator1() As System.Collections.IEnumerator _
     Implements System.Collections.IEnumerable.GetEnumerator
      Return m_list.GetEnumerator
   End Function
End Class

Gru?
---------------------------------------------------
Snoopy sagt - vb@rchiv find ich gut...
Schon gesehen? OSMMapViewer V2 Control