Option Explicit
 
Dim FSO As FileSystemObject
 
Private Sub cmdSearch_Click()
    Dim sPath As String
    Dim sFileToSearchFor As String
 
    Set FSO = New FileSystemObject
 
    ' Startverzeichnis
    sPath = "C:\"
 
    ' Datei, nach der gesucht werden soll
    sFileToSearchFor = "test.txt"
 
    FSO_SearchFile sPath, sFileToSearchFor
End Sub
 
' einzelnen Ordner durchsuchen
Private Sub FSO_SearchFile(ByVal sPath As String, _
    ByVal sFileToSearchFor As String)
 
    Dim Folder As Folder
    Dim SubFolder As Folder
 
    If Right$(sPath, 1) <> "\" Then sPath = sPath & "\"
    lblPath.Caption = sPath
    DoEvents
 
    Set Folder = FSO.GetFolder(sPath)
    If Dir(sPath & sFileToSearchFor) <> "" Then
       ' Datei im Ordner gefunden
       ' --> Pfad in die ListBox eintragen
       List1.AddItem sPath
    End If
 
    ' Ggfs. Fehler "Zugriff verweigert" ignorieren
    On Local Error Resume Next
 
    ' Unterordner
    If Folder.SubFolders.Count > 0 Then
       For Each SubFolder In Folder.SubFolders
         ' Hier wird die Funktion REKURSIV aufgerufen,
         ' um alle weiteren Unterordner des SubFolders
         ' zu ermitteln
         FSO_SearchFile sPath & SubFolder.Name, _
           sFileToSearchFor
       Next
   End If
End Sub