Option Explicit
Private Const WM_PAINT = &HF
Private Const WM_PRINT = &H317
Private Const PRF_CLIENT = &H4&
Private Const PRF_CHILDREN = &H10&
Private Const PRF_OWNED = &H20&
 
Private Declare Function SendMessage Lib "user32" Alias _
      "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, _
      ByVal wParam As Long, ByVal lParam As Long) As Long
 
 
Private Sub Form_Load()
  'Eigenschaften der PicBox, die gedruckt werden soll, festlegen
    With picToPrint
        .Width = picSource.Width
        .Height = picSource.Height
        .Visible = False
    End With
End Sub
 
Private Sub cmdPrint_Click()
  'Focus auf ein Steuerelement ausserhalb der PicBox setzen
    cmdQuit.SetFocus
 
  'Inhalt von picSource -> picToPrint kopieren
    picToPrint.AutoRedraw = True
    SendMessage picSource.hwnd, WM_PAINT, picToPrint.hDC, 0
    SendMessage picSource.hwnd, WM_PRINT, picToPrint.hDC, _
            PRF_CHILDREN + PRF_CLIENT + PRF_OWNED
    picToPrint.Picture = picToPrint.Image
    picToPrint.AutoRedraw = False
 
  'Drucken
    Printer.PaintPicture picToPrint.Image, 0, 0
    Printer.EndDoc
End Sub
 
Private Sub cmdQuit_Click()
  Unload Me
End Sub