Public Function ReadByte(Offset As Long, WindowName As String) As Byte
 
    Dim hwnd As Long
    Dim ProcessID As Long
    Dim ProcessHandle As Long
    Dim Value As Byte
 
    'Try to find the window that was passed in the variable WindowName to this 
    ' function.
    hwnd = FindWindow(vbNullString, WindowName)
 
    If hwnd = 0 Then
 
        'This is executed if the window cannot be found.
        'You can add or write own code here to customize your program.
 
        MsgBox "Could not find process window!", vbCritical, "Read error"
 
        Exit Function
 
    End If
 
    'Get the window's process ID.
    GetWindowThreadProcessId hwnd, ProcessID
 
    'Get a process handle.
    ProcessHandle = OpenProcess(PROCESS_ALL_ACCESS, False, ProcessID)
 
    If ProcessHandle = 0 Then
 
        'This is executed if a process handle cannot be found.
        'You can add or write your own code here to customize your program.
 
        MsgBox "Could not get a process handle!", vbCritical, "Read error"
 
        Exit Function
 
    End If
 
 
    'Read a BYTE value from the specified memory offset.
    ReadProcessMem ProcessHandle, Offset, Value, 1, 0&
 
    'Return the found memory value.
    ReadByte = Value
 
    'It is important to close the current process handle.
    CloseHandle ProcessHandle
 
End Function