Sub NewCreateIndex(strTableName As String, strNewIndexName As String, _
  strNewFldName As String, _
                   boolNewIgnoreNull As Boolean, boolNewUnique As Boolean, _
                   lngSort As Long, _
                   Optional boolPrimary As Boolean = False)
'*******************************************
'Name:      NewCreateIndex (Sub)
'Purpose:   Erstellt einen neuen Index für die Tabelle in der angegebenen 
' Datenbank
'Author:    Thomas Keßler
'Date:      Dezember 01, 2002, 10:05:15
'Inputs:    strTabName = Name der Tabelle, NewIndexName = Name des neuen Indexes
'           NewFldName = Name des neuen Feldes, NewIgnoreNull = Nullwerte 
' ignorieren ?,
'           NewUnique=Index Eindeutig ?, Sort=Sortierung des Feldes ( 
' 0=Aufsteigend, 1=Absteigend)
'           boolPrimary=Primär Index
'Output:
'*******************************************
On Error GoTo ErrHandler
 
    Dim db As DAO.Database
    Dim tdf As DAO.TableDef
    Dim idx As DAO.Index
    Dim fld As DAO.Field
 
    Set db = CurrentDb
    Set tdf = db.TableDefs(strTableName)
 
    '   Erstellen index
    Set idx = tdf.CreateIndex(strNewIndexName)
 
    '   Anfügen Feld an den Index
    Set fld = idx.CreateField(strNewFldName)
    fld.Attributes = lngSort
    idx.Fields.Append fld
 
    idx.Primary = boolPrimary
    idx.IgnoreNulls = boolNewIgnoreNull
    If boolPrimary = True Then
        idx.Unique = True
    Else
        idx.Unique = boolNewUnique
    End If
    '   Anfügen Index an Auflistung
    tdf.Indexes.Append idx
 
Set db = Nothing
 
ExitHere:
    Exit Sub
ErrHandler:
    If Err.Number = 3284 Then
        MsgBox "Indexname bereits vorhanden"
    Else
        Dim strErrString As String
        strErrString = "Error Information..." & vbCrLf
        strErrString = strErrString & "Error#: " & Err.Number & vbCrLf
        strErrString = strErrString & " Description: " & Err.Description & _
          vbCrLf
        MsgBox strErrString, vbCritical + vbOKOnly, "Error in Sub:" & _
        "NewCreateIndex"
    End If
    Resume ExitHere
End Sub

Gru? TommyK