Sub FileToBlob(ByVal FName As String, fld As ADODB.Field, _
                     Optional Threshold As Long = 1048576)
      '
      ' Assumes file exists
      ' Assumes calling routine does the UPDATE
      ' File cannot exceed approx. 2Gb in size
      '
      Dim f As Long, Data() As Byte, FileSize As Long
        f = FreeFile
        Open FName For Binary As #f
        FileSize = LOF(f)
        Select Case fld.Type
          Case adLongVarBinary
            If FileSize > Threshold Then
              ReadToBinary f, fld, FileSize
            Else
              Data = InputB(FileSize, f)
              fld.value = Data
            End If
          Case adLongVarChar, adLongVarWChar
            If FileSize > Threshold Then
              ReadToText f, fld, FileSize
            Else
              fld.value = Input(FileSize, f)
            End If
        End Select
        Close #f
      End Sub
 
      Sub ReadToBinary(ByVal f As Long, fld As ADODB.Field, _
                       ByVal FileSize As Long)
      Dim Data() As Byte, BytesRead As Long
        Do While FileSize <> BytesRead
          If FileSize - BytesRead < BLOCK_SIZE Then
            Data = InputB(FileSize - BytesRead, f)
            BytesRead = FileSize
          Else
            Data = InputB(BLOCK_SIZE, f)
            BytesRead = BytesRead + BLOCK_SIZE
          End If
          fld.AppendChunk Data
        Loop
      End Sub
 
      Sub ReadToText(ByVal f As Long, fld As ADODB.Field, _
                     ByVal FileSize As Long)
      Dim Data As String, CharsRead As Long
        Do While FileSize <> CharsRead
          If FileSize - CharsRead < BLOCK_SIZE Then
            Data = Input(FileSize - CharsRead, f)
            CharsRead = FileSize
          Else
            Data = Input(BLOCK_SIZE, f)
            CharsRead = CharsRead + BLOCK_SIZE
          End If
          fld.AppendChunk Data
        Loop
      End Sub