Public Class frmDGVSync
 
    Dim dt1, dt2 As New DataTable
    Dim dv1, dv2 As New DataView
 
    Dim bs1 As New BindingSource
    Dim bs2 As New BindingSource
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As  _
      System.EventArgs) Handles MyBase.Load
        'eindeutige Schlüsselspalte
        dt1.Columns.Add("ID", GetType(Integer))
        dt1.Columns(0).AutoIncrement = True
        dt1.Columns(0).Unique = True
        dt1.Columns(0).ReadOnly = True
 
        dt1.Columns.Add("Col1", GetType(Double))
        dt1.Columns.Add("Col2", GetType(Double))
 
        'einige Datenzeilen  
        For i As Integer = 1 To 10 : dt1.Rows.Add(i, i, i) : Next i
 
        dt2 = dt1.Copy
 
        bs1.DataSource = dt1
        bs1.Sort = dt1.Columns(1).ColumnName 'Sortierspalte
        dv1 = New DataView(dt1)
 
        bs2.DataSource = dt2
        bs2.Sort = dt2.Columns(1).ColumnName
 
        With DataGridView1
            .DataSource = bs1
            .AllowUserToDeleteRows = False
            .AllowUserToAddRows = False
        End With
 
        DataGridView2.DataSource = bs2
        DataGridView2.ReadOnly = True
 
    End Sub
 
    Private Sub DataGridView1_CellEndEdit(ByVal sender As Object, _
        ByVal e As System.Windows.Forms.DataGridViewCellEventArgs) _
        Handles DataGridView1.CellEndEdit
 
        'Verweis auf aktuelle Tabellenzeile 
        Dim row As DataRow = CType(bs1.Current, DataRowView).Row
        'der geänderte Wert in der Zeile
        Dim newvalue As Object = row(e.ColumnIndex)
        'Schlüsselwert der geänderten Zeile
        Dim id As Integer = CInt(row.Item("ID")) 
        'Zeilenindex mit Schlüsselwert in der zweiten Tabelle 
        Dim rowindex As Integer = bs2.Find("ID", id)
        'geänderten Wert in die zweite Tabelle schreiben 
        CType(bs2(rowindex), DataRowView).Row.Item _
        (dt1.Columns(e.ColumnIndex).ColumnName) = newvalue
    End Sub
 
    Private Sub DataGridView1_DataError(ByVal sender As Object, _
        ByVal e As System.Windows.Forms.DataGridViewDataErrorEventArgs) _
       Handles DataGridView1.DataError
 
        MsgBox("Unzulässige Eingabe:" & e.Exception.Message)
        e.Cancel = True
    End Sub
End Class